File PKGBUILD of Package soundscape

# Maintainer: Алыпов Андрей <and.november@opensuse.org>
  
pkgname=soundscape
pkgver=@SERVICE@
pkgrel=1
pkgdesc="Desktop application for playing a mix of sounds"
arch=(x86_64)
url="https://github.com/ddanilov/soundscape"
groups=()
license=(GPL-3.0-only CC-BY-3.0)
depends=(qt6-base qt6-svg qt6-multimedia qt6-multimedia-ffmpeg pipewire)
makedepends=(cmake help2man ninja qt6-tools zstd)
changelog=${pkgname}.changes
source=("${pkgname}-${pkgver}.tar.xz")
md5sums=('SKIP')
noextract=(${pkgname}-${pkgver}.tar.xz)

prepare() {
  tar xf ${pkgname}-${pkgver}.tar.xz
  sed -i "s|^\(Exec=${pkgname}\)|\1 --minimize --load /usr/share/${pkgname}/examples/ocean/ocean.json|" \
    ${pkgname}-${pkgver}/linux/applications/${pkgname}.desktop
  tar --use-compress-program=unzstd -xvf ${startdir}/ocean.tar.zst -C ${pkgname}-${pkgver}/
}

build() {
  cd ${pkgname}-${pkgver}/
  cmake -B build -GNinja \
    -DCMAKE_INSTALL_PREFIX:PATH="${pkgdir}/usr" \
    -DCMAKE_VERBOSE_MAKEFILE:BOOL=ON \
    -DCMAKE_SKIP_RPATH:BOOL=ON \
    -DAPP_VERSION=${pkgver}
  ninja -C build
}

check() {
  QT_QPA_PLATFORM=offscreen ctest --output-on-failure --force-new-ctest-process \
    -j$(nproc --all) --test-dir ${pkgname}-${pkgver}/build/tests/
}

package() {
  cd ${pkgname}-${pkgver}/
  ninja install -C build
  help2man --no-info --name="is an desktop application for playing a mix of sounds" \
    --output=${pkgname}.1 --locale=C.UTF-8 "QT_QPA_PLATFORM=offscreen build/src/${pkgname}"
  install -vDm 0644 ${pkgname}.1 ${pkgdir}/usr/share/man/man1/${pkgname}.1
  install -vDm 0644 LICENSE -t ${pkgdir}/usr/share/licenses/${pkgname}/
  rm -fv ${pkgdir}/usr/share/doc/${pkgname}/LICENSE
# rm -rfv ${pkgdir}/usr/share/doc/${pkgname}/screenshots/
}