File PKGBUILD of Package pulseaudio-policy-enforcement

## $Id$
# Maintainer: Chupligin Sergey (NeoChapay) <neochapay@gmail.com>

pkgname=pulseaudio-policy-enforcement
pkgver=14.2.47
pkgrel=1
pkgdesc="Pulseaudio module for enforcing policy decisions in the audio domain"
arch=('x86_64' 'aarch64')
url="https://github.com/nemomobile-ux/pulseaudio-policy-enforcement"
license=('LGPLv2+')
depends=('libpulse' 'pulseaudio')
makedepends=('automake' 'autoconf' 'pulsecore-headers' 'pulseaudio-modules-nemo' 'libatomic_ops')
source=("${url}/archive/refs/tags/$pkgver.tar.gz"
	"0001-fix_build.patch")
sha256sums=('df6c11c4a118c281d59a03fa0069c1e3def8359db6e0da424ce73bdb52ac63a3'
	    'e8016cde30ff5d7a0f4e6cacf791fe7ff8bf15f7b94b0fd557b79a89fe6ffcc1')

prepare() {
    cd $pkgname-$pkgver
    pulseaudio --version | sed 's/pulseaudio \|//' > .tarball-version
    patch -p1 --input="${srcdir}/0001-fix_build.patch"
}

build() {
  cd $pkgname-$pkgver
  ./bootstrap.sh --prefix=/usr \
    --sysconfdir=/etc \
    --sbindir=/usr/bin \
    --with-module-dir=/usr/lib/pulseaudio/modules/ \
    --disable-static
    make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
}