File PKGBUILD of Package zls-git

pkgname=zls-git
_srcname=zls
pkgver=0.13.0
 pkgrel=1
pkgdesc="A language server for Zig"
arch=('x86_64')
url="https://github.com/zigtools/zls"
license=('MIT')
depends=('zig-git')
provides=('zls')
conflicts=('zls')
source=(
  "zls.tar"
  "known-folders.tar"
  "diffz.tar"
  "lsp-kit.tar"
)
b2sums=(
  'SKIP'
  'SKIP'
  'SKIP'
  'SKIP'
)

prepare() {
  zig fetch --global-cache-dir vendor known-folders
  zig fetch --global-cache-dir vendor diffz
  zig fetch --global-cache-dir vendor lsp-kit

  sed \
    -e "s/\.pre = \"dev/&.$(echo -n ${pkgver} | sed -E 's/([0-9]+\.){3}r([0-9]+)\.g([0-9a-z]+)/\2", .build = "\3/')/" \
    -e "s/getVersion(b)/zls_version/g" \
    -e "s/\*Build/*std.Build/g" \
    -e "s/Build\.ResolvedTarget/std.&/" \
    -i $_srcname/build.zig
}

build() {
  cd "$_srcname"
  DESTDIR="build" zig build \
    --global-cache-dir ../vendor \
    --system ../vendor/p \
    -p /usr \
    -Doptimize=ReleaseFast \
    -Dcpu=znver3 \
    -Dpie=true
}

package() {
  cd "$_srcname"
  cp -a build/* "$pkgdir"
  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}

# vim: ts=2 sw=2 et: