File PKGBUILD of Package flacon

# Maintainer: Oleksandr Natalenko <oleksandr@natalenko.name>

pkgname=flacon
pkgver=12.0.0
pkgrel=3
pkgdesc="Split single large audio file containing entire album into separate audio tracks"
arch=(x86_64)
url=https://flacon.github.io
license=(LGPL-2.1-or-later)
depends=(hicolor-icon-theme libicuuc.so qt6-base taglib uchardet)
makedepends=(cmake ninja qt6-tools yaml-cpp)
optdepends=('alacenc: For ALAC support'
			'faac: For AAC support'
			'flac: For FLAC support'
			'lame: For MP3 support'
			'mac: For APE support'
			'opus-tools: For OPUS support'
			'sox: For SoX support'
			'ttaenc: For TrueAudio support'
			'vorbis-tools: For OGG support'
			'wavpack: For WavPack support')
source=(https://github.com/flacon/flacon/archive/refs/tags/v${pkgver}.tar.gz)
sha256sums=('78199ff925b7cd0ffeb628d47909ca4172f8ff0d8fd8192bb537e0c012e6f4c6')

build() {
	cmake -S ${pkgname}-${pkgver} \
		-B build \
		-G Ninja \
		-Wno-dev \
		--install-prefix=/usr \
		-DCMAKE_BUILD_TYPE=RelWithDebInfo \
		-DUSE_QT5=OFF \
		-DUSE_QT6=ON

	cmake --build build
}

package() {
	DESTDIR="${pkgdir}" cmake --install build
}