File PKGBUILD of Package swsnr-linux-base

# Maintainer: Sebastian Wiesner <sebastian@swsnr.de>
#
# Copyright Sebastian Wiesner <sebastian@swsnr.de>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted.
#
# THE SOFTWARE IS PROVIDED “AS IS” AND THE AUTHOR DISCLAIMS ALL WARRANTIES WITH
# REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
# AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT,
# INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
# LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR
# OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
# PERFORMANCE OF THIS SOFTWARE.

pkgname=swsnr-linux-base
pkgver=13
pkgrel=1
pkgdesc="Basic system environment on top a Linux kernel"
arch=("any")
url="https://swsnr.de"
license=('0BSD')
options=(!debug !strip)
depends=(
    base
    tar-no-backup
    swsnr-pacman
    swsnr-base-tools
    zram-generator-defaults
    systemd-oomd-defaults
    systemd-shorter-shutdown-timer
    linux
    wireless-regdb
    mkinitcpio
    systemd-ukify
    exfatprogs
    btrfs-progs
    dosfstools
    fwupd
    efibootmgr
    dmidecode
    alsa-utils
    networkmanager
    networkmanager-defaults-privacy
    avahi
    pacman-hook-kernel-install
)
optdepends=(
    'swsnr-intel: Hardware support for intel systems'
)
conflicts=(plymouth linux-zen)
source=(
    resolved.conf
    base.preset
    timesyncd.conf
    sysctl.conf
    kernel-cmdline
    kernel-install.conf
    mkinitcpio.conf
    modprobe.conf
    modules-load.conf
    tmpfiles-force-resolved.conf
)
sha256sums=('35567ff67894d1ca04d0b70ece132f1895a8ec33824c792ce7e8299484e5d471'
            '453a64e90afcda9eec5e43aa2c1eb0fa31093cc88515c0be3671a6330b50cbee'
            'db1c7815953b20315b0fa16833781fc91d942d389c029a5b9a37ee807e328317'
            '014acf48b53f1c7f1ef304f9529f4d7efec605220270931b0944323ffa51ae17'
            '6facdcd934cca6efb93a410b10a3b3e2833ad231bcb17b54233aedfa9d4e8dfa'
            '1acebe38cd460afdbc8fcc3acf38a2ece34513ea81213ed191250b890b12c6b2'
            'e238a44d7549d47004bccf81c08bb555e1ac1958104e3ba9653acf8857d0e6b8'
            'ab5a48b8aa0bb559eed3c8e92ea0d546d42c64e1baad0b2c03e261a57faa8a40'
            '68396daea057923bdfd07ff6aade5938747c2a8f2acd36ebdbcb4be08e4ebef8'
            '252043f73fd43d24f08a87eb0a8beb9455ee95543fa28f9136996064ec62fbda')

package() {
    install -Dpm644 "${srcdir}/base.preset" "${pkgdir}/usr/lib/systemd/system-preset/50-${pkgname}.preset"
    install -Dpm644 "${srcdir}/timesyncd.conf" "${pkgdir}/usr/lib/systemd/timesyncd.conf.d/50-${pkgname}.conf"
    install -Dpm644 "${srcdir}/resolved.conf" "${pkgdir}/usr/lib/systemd/resolved.conf.d/50-${pkgname}.conf"
    install -Dpm644 "${srcdir}/sysctl.conf" "${pkgdir}/usr/lib/sysctl.d/90-${pkgname}.conf"
    install -Dpm644 "${srcdir}/modprobe.conf" "${pkgdir}/usr/lib/modprobe.d/${pkgname}.conf"
    install -Dpm644 "${srcdir}/modules-load.conf" "${pkgdir}/usr/lib/modules-load.d/${pkgname}.conf"
    install -Dpm644 "${srcdir}/mkinitcpio.conf" "${pkgdir}/etc/mkinitcpio.conf.d/10-${pkgname}.conf"
    install -Dpm644 "${srcdir}/tmpfiles-force-resolved.conf" "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}-force-resolved.conf"
    install -Dpm644 "${srcdir}/kernel-install.conf" "${pkgdir}/usr/lib/kernel/install.conf.d/50-${pkgname}.conf"
    install -Dpm644 "${srcdir}/kernel-cmdline" "${pkgdir}/usr/lib/kernel/cmdline"

    # Disable mkinitcpio hooks, as we use kernel-install
    install -Dpm755 -d "${pkgdir}/etc/pacman.d/hooks"
    ln -sf /dev/null "${pkgdir}/etc/pacman.d/hooks/60-mkinitcpio-remove.hook"
    ln -sf /dev/null "${pkgdir}/etc/pacman.d/hooks/90-mkinitcpio-install.hook"
}