File PKGBUILD of Package digitalclock5

# TRANSFORM-RELEASE: 1
# Maintainer: Алыпов Андрей <and.november@opensuse.org>
  
_appname=DigitalClock5
pkgname=digitalclock5
pkgver=@SERVICE@
pkgrel=1
pkgdesc="Very customizable beautiful clock"
arch=(x86_64)
url="https://github.com/Kolcha/DigitalClock5"
groups=()
license=(GPL-3.0-or-later)
depends=(qt6-base qt6-svg qt6-multimedia qt6-multimedia-ffmpeg qt6-imageformats pipewire)
makedepends=(cmake ninja qt6-tools unzip bubblewrap)
changelog=${pkgname}.changes
source=("${pkgname}-${pkgver}.tar.xz")
md5sums=('SKIP')
noextract=(${pkgname}-${pkgver}.tar.xz)

prepare() {
  tar xf ${pkgname}-${pkgver}.tar.xz
  patch -p1 -i ${startdir}/shortest-path-to-skins.patch -d ${pkgname}-${pkgver}/
}

build() {
  cd ${pkgname}-${pkgver}/
  cmake -B build -GNinja \
    -DCMAKE_SKIP_RPATH:BOOL=ON \
    -DCMAKE_INSTALL_PREFIX:PATH="${pkgdir}/usr" \
    -DCMAKE_VERBOSE_MAKEFILE:BOOL=ON
  ninja -C build
}

package() {
  cd ${pkgname}-${pkgver}/
  install -vDm 0644 ${startdir}/${_appname}.desktop -t ${pkgdir}/usr/share/applications/
  install -vDm 0755 ./build/app/${_appname} -t ${pkgdir}/usr/libexec/${_appname}/
  install -dm 0755 ${pkgdir}/usr/bin
  ln -sf /usr/libexec/${_appname}/${_appname} ${pkgdir}/usr/bin/${_appname}
  find ./build/{clock_common,plugin_core,skin_engine}/ -name 'lib*.so' -exec install -vDm 0755 {} -t ${pkgdir}/usr/lib/ \;
  find ./build/plugins/ -name '*.so' -not -name '*sample*' -exec install -vDm 0755 {} -t ${pkgdir}/usr/libexec/${_appname}/plugins/ \;
  install -dm 0755 ${pkgdir}/usr/share/${_appname}
  unzip ${startdir}/skins.zip -d ${pkgdir}/usr/share/${_appname}/
  install -dm 0755 ${pkgdir}/usr/share/icons/hicolor
  unzip ${startdir}/icons.zip -d ${pkgdir}/usr/share/icons/hicolor/
  install -vDm 0644 README.md -t ${pkgdir}/usr/share/doc/${pkgname}/
  install -vDm 0644 LICENSE.txt -t ${pkgdir}/usr/share/licenses/${pkgname}/
}