File PKGBUILD of Package hearts

# Maintainer: Алыпов Андрей <and.november@opensuse.org>
  
pkgname=hearts
pkgver=@SERVICE@
pkgrel=1
pkgdesc="The card game"
arch=(x86_64)
url="https://github.com/Rescator7/Hearts"
groups=()
license=(MIT)
depends=(qt6-base qt6-svg allegro)
makedepends=(librsvg qt6-tools)
changelog=${pkgname}.changes
source=("${pkgname}-${pkgver}.tar.xz")
md5sums=('SKIP')
noextract=(${pkgname}-${pkgver}.tar.xz)

prepare() {
  tar xf ${pkgname}-${pkgver}.tar.xz
  cd ${pkgname}-${pkgver}/
  patch -p1 -i ${startdir}/install.patch
  patch -p1 -i ${startdir}/config_cpp.patch
  patch -p1 -i ${startdir}/mainwindow_cpp.patch
  mkdir -p data/icons/{16x16,24x24,32x32,48x48,64x64,72x72,96x96,128x128,256x256,512x512,scalable}/apps
  cp ${startdir}/${pkgname}.svg ./data/icons/scalable/apps/
  for i in 16 24 32 48 64 72 96 128 256 512 ; do
    rsvg-convert -a -h $i ${startdir}/${pkgname}.svg -o data/icons/$i\x$i/apps/${pkgname}.png
  done
  cp ${startdir}/leaves.jpg backgrounds/leaves.jpg
  rm -fv languages/translation_*.qm
  cat > ./data/${pkgname}.desktop <<-EOF
[Desktop Entry]
Name=Hearts
Name[fr]=La Dame de Pique
Name[ru]=Червы
GenericName=Card Game Hearts
GenericName[fr]=La Dame de Pique
GenericName[ru]=Карточная игра Червы
Exec=${pkgname}
Icon=${pkgname}
Type=Application
Categories=Game;CardGame;
EOF
}

build() {
  cd ${pkgname}-${pkgver}/
  export LANG=C.UTF-8
  qmake6 Hearts.pro \
    PREFIX=/usr
  make -j$(nproc --all) VERBOSE=1
}

package() {
  cd ${pkgname}-${pkgver}/
  make INSTALL_ROOT="${pkgdir}" install
  install -vDm 0644 README.md -t ${pkgdir}/usr/share/doc/${pkgname}/
  install -vDm 0644 LICENSE -t ${pkgdir}/usr/share/licenses/${pkgname}/
}