File PKGBUILD of Package hearts2

# Maintainer: Алыпов Андрей <and.november@opensuse.org>
  
pkgbase=hearts
pkgname=(hearts{,-addons})
pkgver=@SERVICE@
pkgrel=1
pkgdesc="Card game"
arch=(x86_64)
url="https://github.com/Rescator7/Hearts2"
groups=()
license=(MIT)
depends=(allegro qt6-base qt6-svg qt6-multimedia qt6-multimedia-ffmpeg)
makedepends=(cmake ninja qt6-tools sox tar)
changelog=${pkgbase}.changes
source=("${pkgname}-${pkgver}.tar.xz")
md5sums=('SKIP')
noextract=(${pkgname}-${pkgver}.tar.xz)

prepare() {
  tar xf ${pkgname}-${pkgver}.tar.xz
  cd ${pkgname}-${pkgver}/
  mv sounds sounds-wav
  mkdir sounds
  for i in $(find sounds-wav/ -name '[[:digit:]]*.wav' -exec basename -a {} + | cut -d '.' -f1) ; do
    sox sounds-wav/$i.wav sounds/$i.ogg
  done
  sox sounds-wav/Soundwhich*.wav sounds/"Soundwhich - Correct (LittleRainySeasons) [public]".ogg
  sed -i 's/\.wav/.ogg/' sounds.cpp
}

build() {
  cd ${pkgname}-${pkgver}/
  cmake -B build -GNinja \
    -DCMAKE_INSTALL_PREFIX:PATH="/usr" \
    -DCMAKE_VERBOSE_MAKEFILE:BOOL=ON
  ninja -j$(nproc --all) -v -C build
}

check() {
  ctest --output-on-failure --force-new-ctest-process \
    -j$(nproc --all) --test-dir ${pkgname}-${pkgver}/build/
}

package_hearts() {
  license=(MIT)
  optdepends=(hearts-addons)
  cd ${pkgname}-${pkgver}/
  DESTDIR="${pkgdir}" ninja install -C build
  local addonspkg=${pkgdir}-addons
  rm -rvf ${pkgdir}/usr/share/hearts/SVG-cards/Default
  mkdir -p ${addonspkg}/usr/share/hearts/
  mv -v ${pkgdir}/usr/share/hearts/SVG-cards ${addonspkg}/usr/share/hearts/
  mv -v ${pkgdir}/usr/share/hearts/backgrounds ${addonspkg}/usr/share/hearts/
  install -vDm 0644 README.md -t ${pkgdir}/usr/share/doc/${pkgname}/
  install -vDm 0644 LICENSE -t ${pkgdir}/usr/share/licenses/${pkgname}/
}
package_hearts-addons() {
  license=(CC-BY-3.0 CC-BY-4.0 CC0-1.0 LGPL-3.0-only MIT FreeImage)
  depends=(hearts)
}