File PKGBUILD of Package imageviewer

# Maintainer: Алыпов Андрей <and.november@opensuse.org>

_appid=com.github.aliencoweatcake.imageviewer
_appname=ImageViewer
pkgname=imageviewer
pkgver=@SERVICE@
pkgrel=1
pkgdesc="Simple, cross-platform image viewer"
arch=(x86_64)
url="https://github.com/AlienCowEatCake/ImageViewer"
groups=()
license=(GPL-3.0-or-later)
depends=(exiv2 flif freetype2 giflib jasper jbigkit jxrlib lcms2 lerc
 libavif libexif libheif libjpeg-turbo libjxl libmng libpng libraw librsvg
 libtiff libwebp libwmf libyuv openexr openjpeg2 qt6-base qt6-svg resvg zlib)
makedepends=(bubblewrap qt6-tools)
optdepends=(kimageformats qt6-imageformats)
changelog=${pkgname}.changes
source=("${pkgname}-${pkgver}.tar.xz")
md5sums=('SKIP')
noextract=(${pkgname}-${pkgver}.tar.xz)

prepare() {
  tar xf ${pkgname}-${pkgver}.tar.xz
  patch -p1 -i ${startdir}/${pkgname}-desktop.patch -d ${pkgname}-${pkgver}/
  patch -p1 -i ${startdir}/${pkgname}-install.patch -d ${pkgname}-${pkgver}/
}

build() {
  cd ${pkgname}-${pkgver}/
  qmake6 -r ImageViewer.pro \
    CONFIG+="release enable_pkgconfig" \
    CONFIG+="system_thirdparty" \
    CONFIG+="system_resvg" \
    CONFIG+="disable_libbpg" \
    INCLUDEPATH+="/usr/include/Imath" \
    INCLUDEPATH+="/usr/include/freetype2" \
    INCLUDEPATH+="/usr/include/jxrlib" \
    INCLUDEPATH+="/usr/include/openjpeg-2.5"
  make -j$(nproc --all) VERBOSE=1
}

package() {
  cd ${pkgname}-${pkgver}/
  make INSTALL_ROOT="${pkgdir}" install
  install -vDm 0644 README.md -t ${pkgdir}/usr/share/doc/${pkgname}/
  install -vDm 0644 LICENSE.GPLv3 -t ${pkgdir}/usr/share/licenses/${pkgname}/
}