File PKGBUILD of Package ubertooth

# Maintainer: Алыпов Андрей <and.november@opensuse.org>

pkgname=ubertooth
pkgver=2020.12.r1
realver=2020-12-R1
pkgrel=1
pkgdesc="Software and firmware designs for Ubertooth"
arch=(x86_64)
url="https://github.com/greatscottgadgets/ubertooth"
groups=()
license=(GPL-2.0-only)
depends=(libbtbb bluez-libs libpcap libusb)
makedepends=(cmake)
changelog=${pkgname}.changes
# https://github.com/greatscottgadgets/ubertooth/releases/download/2020-12-R1/ubertooth-2020-12-R1.tar.xz
source=("${pkgname}-${realver}.tar.xz")
sha256sums=('93a4ce7af8eddcc299d65aff8dd3a0455293022f7fea4738b286353f833bf986')
noextract=(${pkgname}-${realver}.tar.xz)

prepare() {
  tar xf ${pkgname}-${realver}.tar.xz
}

build() {
  cd ${pkgname}-${realver}/host/
  cmake -B build \
    -DCMAKE_INSTALL_PREFIX:PATH="/usr" \
    -DCMAKE_VERBOSE_MAKEFILE:BOOL=ON \
    -DBUILD_SHARED_LIB:BOOL=ON \
    -DENABLE_PYTHON:BOOL=OFF \
    -DCMAKE_SKIP_RPATH:BOOL=ON \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5
  make -C build -j$(nproc --all)

}

package() {
  cd ${pkgname}-${realver}/host/
  make -C build DESTDIR="${pkgdir}" install
  cd ..
  install -vDm 0644 ubertooth-one-firmware-bin/*.{bin,hex,dfu} \
    -t ${pkgdir}/usr/share/${pkgname}/firmware/
  install -vDm 0644 README.md TRADEMARK -t ${pkgdir}/usr/share/doc/${pkgname}/
  install -vDm 0644 COPYING -t ${pkgdir}/usr/share/licenses/${pkgname}/
}