File PKGBUILD of Package f3d

# Maintainer: Алыпов Андрей <and.november@opensuse.org>

pkgname=f3d
pkgver=2.0.0+git2.f9a4778
pkgrel=1
pkgdesc="Fast and minimalist 3D viewer"
arch=(x86_64)
url="https://f3d-app.github.io/f3d/"
groups=()
license=(BSD)
depends=(alembic assimp draco eigen fmt glew glfw-x11 hdf5 imath libxi libxmu libxt netcdf nlohmann-json opencascade openimagedenoise openmpi ospray pugixml utf8cpp vtk)
makedepends=(cmake help2man jack2)
source=("${pkgname}-${pkgver}.tar.xz")
md5sums=('SKIP')
noextract=(${pkgname}-${pkgver}.tar.xz)

prepare() {
  tar xf ${pkgname}-*.tar.xz
}

build() {
  cd ${pkgname}-*/
  mkdir -p build
  cd build
  cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_TESTING=OFF \
    -DF3D_BINDINGS_JAVA=OFF \
    -DF3D_BINDINGS_PYTHON=OFF \
    -DF3D_LINUX_APPLICATION_LINK_FILESYSTEM=ON \
    -DF3D_LINUX_GENERATE_MAN=ON \
    -DF3D_LINUX_INSTALL_DEFAULT_CONFIGURATION_FILE_IN_PREFIX=ON \
    -DF3D_MODULE_EXTERNAL_RENDERING=OFF \
    -DF3D_MODULE_RAYTRACING=ON \
    -DF3D_PLUGINS_STATIC_BUILD=OFF \
    -DF3D_PLUGIN_BUILD_ALEMBIC=ON \
    -DF3D_PLUGIN_BUILD_ASSIMP=ON \
    -DF3D_PLUGIN_BUILD_DRACO=ON \
    -DF3D_PLUGIN_BUILD_EXODUS=ON \
    -DF3D_PLUGIN_BUILD_OCCT=ON
  make -j$(nproc --all) VERBOSE=1
}

package() {
  cd ${pkgname}-*/build
  make DESTDIR="${pkgdir}" install
}