openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package shotcut (Revision 53c69aadca518670b834a9a629ec13dc)

Currently displaying revision 53c69aadca518670b834a9a629ec13dc , Show latest

# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: nfnty <arch@nfnty.se>

pkgname=shotcut
pkgdesc='Cross-platform Qt based Video Editor'
pkgver=23.03.03
pkgrel=1
arch=('x86_64')
url='https://www.shotcut.org'
license=('GPL3')
depends=('qt6-base' 'qt6-declarative' 'qt6-multimedia'
          'qt6-websockets' 'mlt' 'qt6-multimedia-ffmpeg'
         'movit' 'ffmpeg' 'libx264' 'libvpx' 'lame' 'frei0r-plugins' 
         'ladspa')
optdepends=('swh-plugins: Several audio filters' 'bigsh0t')
makedepends=('qt6-tools' 'cmake' 'ninja' 'gzip' 'p7zip' 'xz' 'zip' 'unzip'
             'bzip2' 'minizip' 'zlib')
options=('debug')
source=("$pkgname-$pkgver.tar.gz::https://github.com/mltframework/shotcut/archive/v$pkgver.tar.gz")
sha512sums=('SKIP')

build() {
  cd "${pkgname}-${pkgver}"

# https://github.com/mltframework/shotcut/issues/1275
  export CXXFLAGS+=" -DSHOTCUT_NOUPGRADE"

cmake \
    -Bbuild \
    -GNinja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DSHOTCUT_VERSION=${pkgver}
  cmake --build build --verbose

ninja -C build translations
}

package() {
  cd "${pkgname}-${pkgver}"
  DESTDIR="${pkgdir}" cmake --install build
}

# vim:set ft=sh sw=2 sts=2 et:

Places

File PKGBUILD of Package shotcut (Revision 53c69aadca518670b834a9a629ec13dc)

Places