File PKGBUILD of Package wiredtiger

# Maintainer: Youngjae Lee <ls4154.lee@gmail.com>
# Contributor: George Rawlinson <george@rawlinson.net.nz>
# Contributor: Christoph Bayer <chrbayer@criby.de>
# Contributor: James P. Harvey <jamespharvey20 at gmail dot com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Fredy García <frealgagu at gmail dot com>

pkgname=wiredtiger
pkgver=11.3.1
pkgrel=1
pkgdesc="High performance, scalable, NoSQL, extensible platform for data management"
arch=("x86_64")
url="https://github.com/wiredtiger/wiredtiger"
license=("GPL")
depends=("lz4" "snappy" "zlib" "zstd")
makedepends=("cmake" "ninja" "swig" "python" "python-setuptools")
checkdepends=("strace")
source=("$pkgname-$pkgver.tar.gz::https://github.com/wiredtiger/wiredtiger/archive/$pkgver.tar.gz"
        intpack_inline_fix.patch::https://github.com/wiredtiger/wiredtiger/commit/7fad4ddc3b79fc0d4eb2cb4756f779a32c9611de.patch
        gcc_15_fix.patch::https://github.com/wiredtiger/wiredtiger/commit/1ef3ead6b4fa911a4270a342c9ae829eb8458ef1.patch)
sha256sums=('ac0417c10cecc686baff5fdc00a7872003fc007993163bafba387fad903d5091'
            'cda5c36072284bad98821f9687dfcf9f6800a78ffbd4b8c3d50dfc04d7c49506'
            '75ed1a57ed03bebaf1533bed7722c70d752accfd88a0dd46fb76fd450a443563')

prepare() {
  cd "$pkgname-$pkgver"

  patch -Np1 -i $srcdir/intpack_inline_fix.patch
  patch -Np1 -i $srcdir/gcc_15_fix.patch

  cmake -G Ninja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DHAVE_BUILTIN_EXTENSION_LZ4=1 \
    -DHAVE_BUILTIN_EXTENSION_SNAPPY=1 \
    -DHAVE_BUILTIN_EXTENSION_ZLIB=1 \
    -DHAVE_BUILTIN_EXTENSION_ZSTD=1 \
    -S . -B build
}

build() {
  cd "$pkgname-$pkgver"
  cmake --build build
}

check() {
  cd "$pkgname-$pkgver/build"
  # -j with no parameter means jobs = number of CPUs
  ctest -j || true
}

package() {
  cd "$pkgname-$pkgver"
  DESTDIR="$pkgdir" cmake --install build
}