File PKGBUILD of Package ZenLib

# $Id$
# Maintainer: MediaArea.net SARL <info@mediaarea.net>
# Contributor: hydro <hydro@freenet.de>

pkgname=libzen
pkgver=0.4.41.20260103
pkgrel=1
pkgdesc="shared library for libmediainfo and mediainfo"
arch=('i686' 'x86_64')
url="http://mediaarea.net"
license=('BSD')
depends=('gcc-libs')
makedepends=('libtool' 'automake' 'autoconf')
source=(${pkgname}_${pkgver}.orig.tar.xz)
md5sums=('b1f6b7f442739189163b48dfd5583745')

build() {
  cd $srcdir/ZenLib/Project/GNU/Library
  [ -x configure ] || sh ./autogen.sh
  [ -f Makefile ] || ./configure --prefix=/usr --enable-shared --disable-static
  make clean
  make
}

package() {
  cd $srcdir/ZenLib/Project/GNU/Library
  make DESTDIR=$pkgdir install
  install -dm 755 $pkgdir/usr/include/ZenLib
  install -m 644 $srcdir/ZenLib/Source/ZenLib/*.h $pkgdir/usr/include/ZenLib
  for i in HTTP_Client Format/Html Format/Http; do
    install -dm0755 $pkgdir/usr/include/ZenLib/$i
    install -m0644 $srcdir/ZenLib/Source/ZenLib/$i/*.h $pkgdir/usr/include/ZenLib/$i
  done
  install -D -m 644 $srcdir/ZenLib/License.txt $pkgdir/usr/share/licenses/libzen/License.txt
}