openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package slade

# Maintainer: Jan Cholasta <grubber at grubber cz>

pkgname=slade
pkgver=3.2.5a
pkgrel=1
pkgdesc='SLADE3 Doom editor'
arch=('i686' 'x86_64')
url='http://slade.mancubus.net/'
license=('GPL')
epoch=1
depends=('bzip2'
         'fluidsynth>=2.2'
         'freeimage'
         'bubblewrap'
         'ftgl'
         'glu'
         'gtk3'
         'libgl'
         'lua'
         'mpg123'
         'sfml>=2.6'
         'webkit2gtk'
         'wxwidgets-gtk3>=3.2'
         'zlib'
         'fmt')
makedepends=('cmake'
             'p7zip'
             'mesa'
             'jack2'
             'clang'
             'ninja')
source=("https://github.com/sirjuddington/SLADE/archive/${pkgver}.tar.gz")
sha256sums=('63d5cb8bff4fa480bf3ca028d2af9860e820bda7fb44675672aef75a7ab06d4e')

build() {
    cd SLADE-${pkgver}

export CC="clang"
    export CXX="clang++"
    export CCACHE_SLOPPINESS=pch_defines,time_macros
    cmake -DCMAKE_BUILD_TYPE=Release \
          -DCMAKE_INSTALL_PREFIX=/usr \
          -DUSE_SYSTEM_FMT=ON \
          -DBUILD_PK3=ON \
          -G Ninja \
          .
    ninja
}

package() {
    cd SLADE-${pkgver}

DESTDIR="$pkgdir" ninja install
}

Places

File PKGBUILD of Package slade

Places