File PKGBUILD of Package slimbook-service

# Maintainer: Bernhard Landauer <bernhard@manjaro.org>
# Maintainer: Mark Wagie <mark at manjaro dot org>

pkgname=slimbook_service
pkgver=0.8.5
pkgrel=2
pkgdesc="Service for Slimbook laptops"
arch=('any')
url="https://github.com/Slimbook-Team/slimbook_service"
license=('GPL-3.0-or-later')
depends=(
  'libayatana-appindicator'
  'libnotify'
  'libslimbook'
  'power-profiles-daemon'
  'python-evdev'
  'python-feedparser'
  'python-gobject'
  'python-pyudev'
  'python-pyzmq'
  'python-requests'
  'python-slimbook'
  'python-dateutil'
)
provides=('slimbook-service')
install="$pkgname.install"
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('a0fdf4d697178570afda2606d1c6133f47e9a0e58ac843d4febcedaa06e51243')

package() {
  cd "$pkgname-$pkgver"
  install -Dm755 slimbook/bin/slimbookindicator -t "$pkgdir/usr/bin/"
  cp -a slimbook/usr "$pkgdir/"
  install -Dm644 90-slimbook-service.preset -t "$pkgdir/usr/lib/systemd/system-preset/"
  install -Dm644 slimbook-service.service -t "$pkgdir/usr/lib/systemd/system/"

  install -d "$pkgdir"/usr/share/{applications,icons/hicolor/scalable/apps}
  ln -s /usr/share/slimbook/slimbook-indicator.desktop "$pkgdir/usr/share/applications/"
  ln -s /usr/share/slimbook/icons/slimbook_be1ofus_{dark,light}.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/"
  ln -s /usr/share/slimbook/icons/slimbook-status-active-{dark,light}.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/"
  ln -s /usr/share/slimbook/icons/slimbook-status-attention-{dark,light}.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/"
}