File PKGBUILD of Package miraclecast

gitdate=20240713
gitrev=937747f
gitcomm=937747fd4de64a33bccf5adb73924c435ceb821b
gitrel=git%{gitdate}.%{gitrev}

pkgname=miraclecast
pkgver=${gitdate}
pkgrel=2
pkgdesc='Wifi-Display / Miracast Implementation'
license=('LGPL-2.1-or-later AND GPL-2.0-or-later')
url='https://github.com/albfan/miraclecast'
arch=('i686' 'x86_64' 'armv6h' 'armv7h')

source=(
	"${gitcomm}.tar.gz"
)

sha256sums=(
	'SKIP'
)

depends=(
	glib2
	gstreamer
	iproute2
	readline
	'systemd>=221'
)
makedepends=(
	automake
	gcc
	libtool
)
# optdepends=()
# options=()

backup=(
	etc/dbus-1/system.d/org.freedesktop.miracle.conf
)

prepare() {
	cd "${pkgname}-${gitcomm}"

	autoreconf -fiv

	# Do not install miracle-omxplayer, it's deprecated
	# See https://github.com/popcornmix/omxplayer
	sed -i -e 's/miracle-omxplayer//' res/Makefile.am
}


build() {
	cd "${pkgname}-${gitcomm}"

	export IP_BINARY=/usr/bin/ip

	./configure

	make
}


check() {
	cd "${pkgname}-${gitcomm}"

	make --keep-going check
}


package() {
	cd "${pkgname}-${gitcomm}"

	make DESTDIR="${pkgdir}/" install
}