File PKGBUILD of Package scorched3d

use_lua_ver='5.1'



pkgname=scorched3d
pkgver=44.2
pkgrel=0
pkgdesc='Game based loosely on the classic DOS game Scorched Earth'
license=('GPL-2.0-or-later')
url="https://github.com/bberberov/${pkgname}"
arch=('i686' 'x86_64')

source=(
	"v${pkgver}.tar.gz"
	"${pkgname}.desktop"
)

sha256sums=(
	'SKIP'
	'SKIP'
)

makedepends=(
	autoconf
	automake
	gcc
	perl
	pkgconfig
)
depends=(
	sdl_net
	expat
	fftw
	freealut
	freetype2
	glew
	freeglut
	libjpeg-turbo

	lua51

	libogg
	openal
	libvorbis

	wxwidgets-gtk3

	xdg-utils

	zlib
)
# optdepends=()
# options=()



prepare() {
	cd "${pkgname}-${pkgver}"
	cd scorched

	# Generate Makefile.am files first !!!
	cd scripts
	perl createAMMakefile.pl
	cd ..
}



build() {
	cd "${pkgname}-${pkgver}"
	cd scorched

	# # TEST no LTO
	# export CFLAGS="${CFLAGS} -fno-lto"
	# export CXXFLAGS="${CXXFLAGS} -fno-lto"
	# export LDFLAGS="${LDFLAGS} -fno-lto"

	autoreconf -fiv

	./configure \
		--with-system-lua="lua-${use_lua_ver}" \
		--datadir="/usr/share/${pkgname}" \
		--with-docdir="/usr/share/doc/${pkgname}"

	make
}



package() {
	cd "${pkgname}-${pkgver}"
	cd scorched

	make DESTDIR="${pkgdir}/" install

	# Install .desktop file and icon
	install -D -m 0644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
	install -D -m 0644 data/images/tank2.png          "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
}