File PKGBUILD of Package manaverse

pkgname=manaverse
url=="https://manaverse.germantmw.de"
pkgver=1.9.3.23
pkgrel=2
arch=('i686' 'x86_64')
pkgdesc="ManaVerse is a 2D MMORPG game advanced client for games based on eAthena fork The Mana World (tmwAthena/Evol2)"
license=('GPL-2.0-or-later')
makedepends=('automake' 'autoconf' 'binutils' 'curl' 'gcc' 'gettext' 'jack2' 'libpng' 'libtool' 'libxml2' 'make' 'sdl_gfx' 'sdl_image' 'sdl_mixer' 'sdl_net' 'sdl_ttf' 'zlib')
depends=('xsel' 'xdg-utils')
optdepends=('mumble: Optionally integrates with Mumble for positional audio support via the Mumble Link plugin'
	'gdb: generate backtrace for filing bug reports'
	'valgrind: to help track down memory-related issues for filing bug reports')
source=("https://git.themanaworld.org/mana/plus/-/archive/v${pkgver}/plus-v${pkgver}.tar.bz2"
	"wallpaper-ctime.patch"
	"dumplibs-implicit-comversion.patch"
	"dyecmd-ctime.patch"
	"libxml-include-parser.patch"
	"chatrecv-cstdint.patch"
	"traderecv-cstdint.patch")
sha256sums=('9b56bd56b1d955d4342444d274e4f5877206c9c9a1f02f8c8b1066ef26cb5edf'
	'd7358430c7ba7bf56719ee6ef6f1b8c639c2d376c584d62eaff5e1872b0b84a6'
	'f5b0d6cbb294aeb09ce4fd5ee8f06f37890708c7881c867916b46597596af351'
	'9b3b35d28c06068813e8772d26c05f3176aa474d2515ec0aabdbc804aae5f4a4'
	'd3bba37f6a25a2894684e78833e8c6395c53d8911adb2924eccfbef9d2cf0591'
	'26ace6809a30e5376321a724c99d86dfe174a7733f40f6bce2d0629339d0e250'
	'fd831a6756eccaee0aa30c4dddd295196158b5f19e2f9f18f2f757c1a7bdba99')

prepare() {
  cd "plus-v${pkgver}"
  patch -p1 -i "${srcdir}/wallpaper-ctime.patch"
  patch -p1 -i "${srcdir}/dumplibs-implicit-comversion.patch"
  patch -p1 -i "${srcdir}/dyecmd-ctime.patch"
  patch -p1 -i "${srcdir}/libxml-include-parser.patch"
  patch -p1 -i "${srcdir}/chatrecv-cstdint.patch"
  patch -p1 -i "${srcdir}/traderecv-cstdint.patch"
  autoreconf -i
}

build() {
  cd "plus-v${pkgver}"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games \
    --enable-tmwa
  cd po
  make update-gmo
  cd ..
  make
}

package() {
  cd "plus-v${pkgver}"
  make DESTDIR="${pkgdir}" install
}