File PKGBUILD of Package manaverse-testing

pkgname=manaverse-testing
url="https://manaverse.germantmw.de"
pkgver=1.0
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="ManaVerse is a 2D MMORPG game advanced client for games based on eAthena fork The Mana World (tmwAthena/Evol2)"
license=('GPL-2.0-or-later')
makedepends=('automake' 'autoconf' 'binutils' 'curl' 'gcc' 'gettext' 'jack2' 'libpng' 'libtool' 'libxml2' 'make' 'sdl_gfx' 'sdl_image' 'sdl_mixer' 'sdl_net' 'sdl_ttf' 'zlib')
depends=('xsel' 'xdg-utils')
optdepends=('mumble: Optionally integrates with Mumble for positional audio support via the Mumble Link plugin'
	'gdb: generate backtrace for filing bug reports'
	'valgrind: to help track down memory-related issues for filing bug reports')
source=("verse-v${pkgver}.tar.bz2")
sha256sums=('7fbf39ad2c3f59e689c8435187ecf81e80a428b04be352373d10f23ed188d801')

prepare() {
  cd "verse-v${pkgver}"
  autoreconf -i
}

build() {
	cd "verse-v${pkgver}"
	./configure \
  		--enable-checks \
		--enable-memdebug \
		--enable-asserts \
		--enable-glibcdebug \
		--enable-stldebug \
		--enable-openglerrors \
		--enable-werror \
		--enable-tcmalloc \
		--prefix=/opt/manaverse-testing \
		--datadir=/opt/manaverse-testing/share/games \
		--enable-tmwa
	cd po
	make update-gmo
	cd ..
	make
}

package() {
	cd "verse-v${pkgver}"
	make DESTDIR="${pkgdir}" install
}