File PKGBUILD of Package libquentier-development

# Maintainer: Dmitry Ivanov <dm.vl.ivanov@gmail.com>
pkgname=libquentier
pkgver=0.8.0
pkgrel=1
pkgdesc="Set of Qt/C++ APIs for feature rich desktop clients for Evernote service"
arch=('i686' 'x86_64')
url="https://github.com/d1vanov/libquentier"
license=('LGPL-3')

makedepends=(
	'cmake'
	'coreutils'
	'doxygen'
	'qt5-tools'
	'boost'
	'doxygen'
	'graphviz'
	'xorg-server-xvfb'
	'gzip'
	'gtest'
)

depends=(
	'qt5-base'
	'qt5-webengine'
	'qt5-websockets'
	'qevercloud'
	'qtkeychain'
	'hunspell'
	'openssl'
	'libxml2'
	'tidy'
)

source=("${pkgname}-${pkgver}.tar.gz")
md5sums=('SKIP')

prepare() {
    cd "${pkgname}-${pkgver}"
	mkdir -p build
	cd build
	cmake ../ -DUSE_QT5=1 \
		  -DQt5_LUPDATE_EXECUTABLE=/usr/bin/lupdate-qt5 \
		  -DQt5_LRELEASE_EXECUTABLE=/usr/bin/lrelease-qt5 \
		  -DLIB_QUENTIER_BUILD_INFO="OpenSUSE build service, unstable. $(date --utc '+%Y-%m-%d %H:%M') UTC"
}

build() {
    cd "${pkgname}-${pkgver}/build"
	make
	make lupdate
	make lrelease
	make doc
}

check() {
    cd "${pkgname}-${pkgver}/build"
	xvfb-run make check
}

package() {
    cd "${pkgname}-${pkgver}/build"
	make DESTDIR="$pkgdir" install
	install -Dm644 ../COPYING.LESSER "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
}