File PKGBUILD of Package quentier-development

# Maintainer: Dmitry Ivanov <dm.vl.ivanov@gmail.com>
pkgname=quentier
pkgver=0.5.0
pkgrel=1
pkgdesc="Cross-platform desktop Evernote client"
arch=('i686' 'x86_64')
url="https://github.com/d1vanov/quentier"
license=('GPL-3')

makedepends=(
	'cmake'
    'coreutils'
	'doxygen'
	'qt5-tools'
	'boost'
	'xorg-server-xvfb'
	'google-breakpad'
)

depends=(
	'qt5-base'
	'qevercloud'
	'libquentier'
)

source=("${pkgname}-${pkgver}.tar.gz")
md5sums=('SKIP')

prepare() {
	cd "${pkgname}-${pkgver}"
	mkdir -p build
	cd build
	cmake ../ -DUSE_QT5=1 \
		  -DQt5_LUPDATE_EXECUTABLE=/usr/bin/lupdate-qt5 \
		  -DQt5_LRELEASE_EXECUTABLE=/usr/bin/lrelease-qt5 \
		  -DBREAKPAD_ROOT=/usr \
          -DQUENTIER_BUILD_INFO="OpenSUSE build service, unstable. $(date --utc '+%Y-%m-%d %H:%M') UTC"
}

build() {
	cd "${pkgname}-${pkgver}/build"
	make
	make lupdate
	make lrelease
}

check() {
	cd "${pkgname}-${pkgver}/build"
	xvfb-run make check
}

package() {
	cd "${pkgname}-${pkgver}/build"
	make DESTDIR="$pkgdir" install
	install -Dm644 ../COPYING "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
}