File PKGBUILD of Package libva-intel-vaapi-driver-irql

# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Serhii Starovoitov <drommer.94@gmail.com>

pkgname=libva-intel-vaapi-driver-irql
pkgver=2.4.4
pkgrel=1
pkgdesc='VA-API implementation for Intel G45 and HD Graphics family (fork by irql)'
arch=('x86_64')
url="https://github.com/irql-notlessorequal/intel-vaapi-driver"
license=('MIT')
depends=('libva' 'libdrm')
makedepends=('intel-gpu-tools' 'meson')
optdepends=('libva-intel-hybrid-driver: Provides partially support for WebM project VPx codecs on Haswell and Skylake')
conflicts=('libva-intel-driver' 'libva-intel-vaapi-driver')
provides=("libva-intel-driver=$pkgver")
source=("$pkgname-$pkgver.tar.gz")
sha256sums=('SKIP')

prepare() {
  cd "$pkgname-$pkgver"
  # Only relevant if intel-gpu-tools is installed, since then the shaders will be recompiled
  sed -i '1s/python$/&2/' "src/shaders/gpp.py"
}

build() {
  CFLAGS+=' -fcommon'
  arch-meson \
  -Dwith_x11=yes \
  -Dwith_wayland=yes \
  -Denable_hybrid_codec=true \
  "$pkgname-$pkgver" build
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  install -Dm644 "$pkgname-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
}