openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package svp4

# Maintainer: Drommer <drommer@github.com>
# Contributor: Martin Rys <rys.rs/contact>
# Contributor: phiresky <phireskyde+git@gmail.com>

_pkgname=svp4-manager
pkgname=svp4
pkgver=4.6.263
pkgrel=1
pkgdesc="SmoothVideo Project 4 (SVP4)"
arch=('x86_64')
url="https://www.svp-team.com"
license=('custom')
depends=('libmediainfo' 'libusb' 'lsof' 'vapoursynth' 'qt5-svg' 'qt5-script' 'qt5-declarative' 'xdg-utils')
makedepends=('p7zip')
optdepends=('mpv: Video player'
            'ocl-icd: for GPU acceleration'
            'python-certifi: youtube-dl extension - Basic support'
            'python-pycryptodomex: youtube-dl extension - For decrypting AES-128 HLS streams and various other data'
            'python-websockets: youtube-dl extension - For downloading over websocket'
            'vlc: Video player')
options=(!strip)
source=("https://www.svp-team.com/files/svp4-linux.${pkgver}.tar.bz2"
        "com.svp-team.manager.desktop")
sha256sums=('1f24435451d59936a7fd28b7423190a42df36b7d306b2d747741e4efda171bdf'
            '1d684abe084e49f7ac5871b920c72a7190377bfcb20e318a53a2633a104eb860')

prepare() {
  rm -rf "${srcdir}/installer"
  mkdir -p "${srcdir}/installer"

echo "Finding 7z archives in installer..."
  LANG=C grep --only-matching --byte-offset --binary --text $'7z\xBC\xAF\x27\x1C' "${srcdir}/svp4-linux-64.run" |
    cut -f1 -d: |
    while read ofs; do
      dd if="${srcdir}/svp4-linux-64.run" bs=1M iflag=skip_bytes status=none skip="${ofs}" of="${srcdir}/installer/bin-${ofs}.7z"
    done

echo "Extracting 7z archives from installer..."
  for f in "${srcdir}/installer/"*.7z; do
    7z -bd -bb0 -y x -o"${srcdir}/extracted/" "${f}" || true
  done
}

package() {
  mkdir -p $pkgdir/{opt/svp4,usr/bin,usr/share/licenses/svp4}

mv -f $srcdir/extracted/licenses/* $pkgdir/usr/share/licenses/$pkgname
  mv -f $srcdir/extracted/* $pkgdir/opt/$pkgname
  chmod -R +rX $pkgdir/opt/$pkgname

install -Dm644 $srcdir/com.svp-team.manager.desktop -t $pkgdir/usr/share/applications
  ln -s /opt/svp4/SVPManager $pkgdir/usr/bin/$_pkgname

for res in 32 48 64 128; do
    install -Dvm644 $pkgdir/opt/$pkgname/svp-manager4-$res.png $pkgdir/usr/share/icons/hicolor/${res}x${res}/apps/$_pkgname.png
  done

rm -rf $pkgdir/opt/$pkgname/{licenses,manual,INSTALL,*.sh,*.png}
}

Places

File PKGBUILD of Package svp4

Places