File PKGBUILD of Package Webcamoid

# Maintainer: Gonzalo Exequiel Pedone <hipersayan DOT x AT gmail DOT com>

pkgrealname=webcamoid
pkgname=${pkgrealname}-gstreamer
pkgver=7.2.1
pkgrel=1
pkgdesc="Webcamoid is a full featured webcam capture application."
url='https://webcamoid.github.io/'
license=('GPL')
arch=('i686' 'x86_64' 'armv6h')
depends=('qt5-quickcontrols' 'qt5-svg' 'libpulse' 'v4l-utils' 'gst-plugins-base-libs')
optdepends=('v4l2loopback-dkms: Virtual camera support'
            'gst-plugins-base'
            'gst-plugins-good'
            'gst-plugins-bad'
            'gst-plugins-ugly')
makedepends=('qt5-tools')
conflicts=('webcamoid')
provides=('webcamoid')
source=("https://github.com/${pkgrealname}/${pkgrealname}/archive/${pkgver}.tar.gz")
sha256sums=('d6fc13352a0e5f5ab4f910f69a7f4e3bedf0655193f833e3443a0ae6b0142a3d')

build() {
    cd "$srcdir/${pkgrealname}-${pkgver}"
    qmake-qt5 Webcamoid.pro USE_GSTREAMER=1
    make
}

package() {
    cd "$srcdir/${pkgrealname}-${pkgver}"
    make INSTALL_ROOT="${pkgdir}" install
}