File PKGBUILD of Package pidgin

pkgname=pidgin
pkgver=2.14.14
pkgrel=4
pkgdesc="Multi-protocol instant messaging client with libpurple library"
arch=('x86_64')
url="https://pidgin.im/"
license=('GPL')
depends=('bubblewrap' 'startup-notification' 'gtkspell' 'libxss' 'nss' 'libsasl' 'libsm' 
         'libidn' 'libgadu' 'farstream' 'libnsl' 'avahi' 'ca-certificates' 
         'libnm' 'dbus-glib' 'libxcrypt' 'gst-plugins-base' 'gst-plugins-good' 
         'hicolor-icon-theme')
makedepends=('python' 'intltool' 'tk')
optdepends=('aspell: for spelling correction'
            'tk: for Tcl/Tk plugins')
options=('!emptydirs')
source=(https://downloads.sourceforge.net/project/pidgin/Pidgin/$pkgver/$pkgname-$pkgver.tar.bz2)
sha1sums=('512c2c2a88b1e8f9b20d06e50d0fb936bf8ec45e')

build() {
  cd $pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --disable-schemas-install \
    --disable-gevolution \
    --disable-meanwhile \
    --disable-gnutls \
    --enable-cyrus-sasl \
    --disable-doxygen \
    --enable-nm \
    --disable-consoleui \
    --with-system-ssl-certs=/etc/ssl/certs

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  find "$pkgdir/usr/lib/perl5" -name perllocal.pod -delete
}