File PKGBUILD of Package quickshell

# Maintainer: Entailz <entail-wraps0r at icloud dot com>

pkgname=quickshell
pkgver=0.2.1
pkgrel=6
pkgdesc='Flexible toolkit for making desktop shells with QtQuick'
arch=(x86_64 aarch64)
url='https://git.outfoxxed.me/quickshell/quickshell'
options=(!strip)
license=('LGPL-3.0-only')
depends=(
  'qt6-declarative'
  'qt6-base'
  'qt6-wayland'
  'pam'
  'polkit'
  'libglvnd'
  'jemalloc'
  'qt6-svg'
  'libpipewire'
  'libxcb'
  'wayland'
  'libdrm'
  'mesa'
)
makedepends=(
  'spirv-tools'
  'qt6-shadertools'
  'wayland'
  'wayland-protocols'
  'cli11'
  'ninja'
  'cmake'
  'pkgconf'
  'polkit'
  'vulkan-headers'
)

options=(!debug)

source=(v"$pkgver.tar.gz"
  quickshell-check.hook)

sha256sums=('SKIP'
            '8543e21aeaaa5441b73a679160e7601a957f16c433e8d6bd9257e80bd0e94083')
b2sums=('SKIP'
        'c729d8c05d0490eda0a4095d831f7fe4f2873debe0dd3dbb0de41a801ed652a885de7048cecc26eaddec9d22e68a7d00552ad3f3db96d80041671192faf0afe0')

build() {
  cd "$pkgname-$pkgver"
  local cmake_options=(
        -D CMAKE_BUILD_TYPE=MinSizeRel
        -D DISTRIBUTOR="AUR (package: quickshell)"
        -D DISTRIBUTOR_DEBUGINFO_AVAILABLE=NO
        -D CRASH_REPORTER=Off
        -D CMAKE_INSTALL_PREFIX=/usr
        -D INSTALL_QML_PREFIX=lib/qt6/qml
  )
  
  cmake -G Ninja -B build -Wno-dev "${cmake_options[@]}"
  cmake --build build
}

package() {
  install -Dm644 "quickshell-check.hook" -t "$pkgdir/usr/share/libalpm/hooks"
  cd "$pkgname-$pkgver"
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
}

post_install() {
    update-desktop-database -q
    xdg-icon-resource forceupdate
}