File PKGBUILD of Package lsb-release-archlinux

# Maintainer: Jonas Witschel <diabonas@archlinux.org>
# Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Malte Rabenseifner <malte@zearan.de>
# Contributor: John Gerritse <reaphsharc@gmail.com>

pkgname=lsb-release
_pkgname=lsb-release
pkgver=2.0.48
_commit=3cf51039933d03ef15388b75d30baa5d5e09a1a0
pkgrel=1
pkgdesc="LSB version query program"
arch=('any')
url="https://refspecs.linuxfoundation.org/lsb.shtml"
license=('GPL')
depends=('sh' 'gzip')
makedepends=('git')
#source "git+https://github.com/LinuxStandardBase/lsb-samples.git#commit=$_commit"
# => _service recompress obs_scm lsb-samples-3cf51039933d03ef15388b75d30baa5d5e09a1a0.20040630T173034~3cf5103.obscpio.xz
source=('lsb-release-2.0.48.tar.xz'
        'lsb-release'
        'lsb_release_description.patch'
        'lsb_release_make_man_page_reproducible.patch')
md5sums=('b64c2fd3f965d230fc5d98def4169814'
         'd4ffa5402737dd89f443c579d936db9d'
         '72f562d8eaa8915ab85fba13e68c8d68'
         '38643eccbab543e6cfb2fa8f875e0d1e')


prepare() {
	cd ${_pkgname}-${pkgver}/src
	patch -Np0 -i "$srcdir/lsb_release_description.patch"
	patch -Np1 -i "$srcdir/lsb_release_make_man_page_reproducible.patch"
}

build() {
	cd ${_pkgname}-${pkgver}/src
	make
}

package() {
	cd ${_pkgname}-${pkgver}/src
	install -Dm644 lsb_release.1.gz -t "$pkgdir/usr/share/man/man1"
	install -Dm755 lsb_release -t "$pkgdir/usr/bin"
	install -Dm644 "$srcdir/lsb-release" -t "$pkgdir/etc"
}