File PKGBUILD of Package OpenBoard-Qt6

pkgname=openboard-qt6
pkgver=1.7.4
_src_folder="OpenBoard-1.7.4"
pkgrel=1
pkgdesc="Interactive whiteboard software for schools and universities"
arch=('x86_64')
url="http://openboard.ch/index.en.html"
license=('GPL3')
depends=('qt6-base' 'qt6-multimedia' 'qt6-multimedia-ffmpeg' 'qt6-svg' 'qt6-webengine' 'libxdamage' 'openssl' 'ffmpeg' 'quazip-qt6' 'poppler' 'bubblewrap-suid')
makedepends=('patch' 'cmake' 'qt6-tools' 'ninja')
source=(OpenBoard-1.7.4.tar.gz)
source+=(9117-disable-software-update.patch)
source+=(9222-version-1.7.4rc-250711.patch)
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

prepare() {
  cd "$srcdir"/$_src_folder
  patch -p1 < "$srcdir"/9117-disable-software-update.patch
  patch -p1 < "$srcdir"/9222-version-1.7.4rc-250711.patch
}

build() {
  cd "$srcdir"/$_src_folder
  mkdir build
  cd build
  cmake -S .. -B . -G Ninja -DCMAKE_INSTALL_PREFIX:PATH=/usr -DCMAKE_CXX_STANDARD=20
  cmake --build .
}

package() {
  cd "$srcdir"/$_src_folder/build
  DESTDIR="$pkgdir" cmake --install .
}