File PKGBUILD of Package OpenBoard

pkgname=openboard
pkgver=1.7.4
_src_folder="OpenBoard-1.7.4"
pkgrel=1
pkgdesc="Interactive whiteboard software for schools and universities"
arch=('x86_64')
url="http://openboard.ch/index.en.html"
license=('GPL3')
depends=('qt5-base' 'qt5-multimedia' 'qt5-svg' 'qt5-webengine' 'libxdamage' 'openssl' 'ffmpeg' 'quazip' 'poppler')
makedepends=('patch' 'cmake' 'qt5-tools' 'ninja')
source=(OpenBoard-1.7.4.tar.gz)
source+=(1255-fix-thumbnail-size.patch)
source+=(1261-fix-check-valid-document.patch)
source+=(9117-disable-software-update.patch)
source+=(9219-version-1.7.4rc-250520.patch)
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP')

prepare() {
  cd "$srcdir"/$_src_folder
  patch -p1 < "$srcdir"/1255-fix-thumbnail-size.patch
  patch -p1 < "$srcdir"/1261-fix-check-valid-document.patch
  patch -p1 < "$srcdir"/9117-disable-software-update.patch
  patch -p1 < "$srcdir"/9219-version-1.7.4rc-250520.patch
}

build() {
  cd "$srcdir"/$_src_folder
  mkdir build
  cd build
  cmake -S .. -B . -G Ninja -DCMAKE_INSTALL_PREFIX:PATH=/usr -DCMAKE_CXX_STANDARD=20
  cmake --build .
}

package() {
  cd "$srcdir"/$_src_folder/build
  DESTDIR="$pkgdir" cmake --install .
}