File PKGBUILD of Package dino

pkgname=dino
pkgver=0.0
pkgrel=0
pkgdesc="Simple and modern Jabber/XMPP client written in vala"
arch=('x86_64' 'aarch64')
url="https://github.com/dino/dino"
license=('GPL3')
depends=('glib2>=2.38' 'glib-networking' 'gtk4' 'gpgme' 'libgee>=0.10' 'libgcrypt' 'libsoup3' 'sqlite' 'qrencode' 'gstreamer' 'gst-plugins-base' 'gst-plugins-good' 'webrtc-audio-processing' 'libnice' 'libsrtp' 'libadwaita' 'libsignal-protocol-c')
makedepends=('cmake' 'vala>=0.34' 'ninja')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("dino-${pkgver}.tar.xz::https://github.com/dino/dino/archive/master.tar.xz")
sha512sums=('SKIP')

# Any or all of the following plugin can be disabled: omemo, openpgp, http-files. Populate following string as per your needs and uncomment it
#_DISABLE_PLUGINS="--disable-plugin='omemo;openpgp;http-files'"

build() {
    cd "${srcdir}/dino-${pkgver}"
    echo "PRERELEASE ${pkgver}" > VERSION
    ./configure $_DISABLE_PLUGINS --prefix="/usr" --with-tests --with-libsignal-in-tree CC="$CC" CFLAGS="$CFLAGS" VALACFLAGS="$VALACFLAGS"
    make
}

package() {
    cd "${srcdir}/dino-${pkgver}"
    make DESTDIR="${pkgdir}/" install
}

check() {
    cd "${srcdir}/dino-${pkgver}"
    echo "Executing xmpp-vala-test:"
    build/xmpp-vala-test
}