File PKGBUILD of Package wireshark-git

# Maintainer: Daniel Nagy <danielnagy at gmx de>

pkgbase=wireshark-git
pkgname=wireshark-git
pkgver=51933.b2689ab
pkgrel=1
pkgdesc="A free network protocol analyzer for Unix/Linux. GIT version"
arch=('i686' 'x86_64')
license=('GPL2')
makedepends=('git' 'gtk3' 'qt5-base' 'libpcap' 'gnutls' 'c-ares' 'e2fsprogs' 'lua52' 'portaudio' 'geoip' 'libsmi' 'krb5' 'perl-parse-yapp' 'python2' 'python')
depends=('krb5' 'libpcap' 'bash' 'gnutls'  'glib2' 'lua' 'qt5-base')
install=wireshark.install
provides=(wireshark wireshark-cli wireshark-qt)
replaces=(wireshark-cli)
conflicts=(wireshark wireshark-cli wireshark-qt)
url="http://www.wireshark.org/"
sha1sums=('SKIP')
_gitmod=${pkgbase%-git}
source=("$_gitmod-$pkgver.tar.xz")
conflicts=('wireshark-gtk')
options=('strip' '!libtool')
#install=$pkgname.install-${pkgver}


prepare() {
  cd $_gitmod-$pkgver
  patch -Np1 -i $startdir/disable-c++-compat.patch
}

build() {
    cd $srcdir/$_gitmod-$pkgver
    ./autogen.sh

    mkdir -p $srcdir/build
    cd $srcdir/build

    /usr/lib/python2.7/Tools/scripts/reindent.py $srcdir/$_gitmod-$pkgver/tools/ncp2222.py

    $srcdir/$_gitmod-$pkgver/configure \
    --prefix=/usr \
    --with-ssl \
    --with-krb5 \
    --with-zlib=yes \
    --with-lua \
    --with-qt \
    --with-portaudio \
    --with-python=/usr/bin/python2 \
    --enable-aircap \
    LDFLAGS="-llua" \
    CFLAGS="-Wno-error=old-style-definition -Wno-error=clobbered -Wno-error=unused-but-set-variable -fno-unit-at-a-time"

    make ${MAKEFLAGS} PYTHON=/usr/bin/python2 
}



package() {

  cd $srcdir/build

  make DESTDIR="${pkgdir}" install
  
  
  #wireshark uid group is 150
  chgrp 150 "${pkgdir}/usr/bin/dumpcap"
  chmod 754 "${pkgdir}/usr/bin/dumpcap"
  #rm -f "${pkgdir}/usr/bin/wireshark" "${pkgdir}/usr/bin/wireshark-qt"
  cp *.h $srcdir/$_gitmod-$pkgver
  cd $srcdir/$_gitmod-$pkgver
  # Headers
  install -dm755 "${pkgdir}"/usr/include/${pkgbase%-git}/{epan/{crypt,dfilter,dissectors,ftypes},wiretap,wsutil}
  
  install -m644 config.h register.h ws_symbol_export.h "${pkgdir}/usr/include/${pkgbase%-git}"
  for d in epan epan/crypt epan/dfilter epan/dissectors epan/ftypes wiretap wsutil; do
    install -m644 ${d}/*.h "${pkgdir}"/usr/include/${pkgbase%-git}/${d}
  done
  
  cd $pkgdir/usr/lib/
      ln -s libwsutil.so.0 libwsutil.so.3
    ln -s libwiretap.so.0 libwiretap.so.3
}