File PKGBUILD of Package qlcplus

# Original author: Jerome Lebleu <jerome dot lebleu at mailoo dot org>

pkgname=qlcplus
pkgver=4.14.4
pkgrel=0
pkgdesc="Q Light Controller Plus - The open DMX lighting desk software for controlling professional lighting fixtures."
arch=('i686' 'x86_64')
url="http://qlcplus.org/"
license=('APACHE')
depends=('qt6-declarative' 'qt6-multimedia-gstreamer' 'qt6-serialport' 'qt6-svg' 'qt6-websockets' 'libftdi-compat' 'libsndfile' 'libmad' 'fftw' 'libcurl-gnutls' 'mesa')
makedepends=('tar' 'qt6-tools' 'cmake' 'shared-mime-info' 'desktop-file-utils')
# ola need to be installed at build time for the plugin to be compiled
optdepends=('ola: Open Lighting Architecture plugin')
conflicts=('qlc' 'qlc-svn')
install=${pkgname}.install
source=("${pkgname}-${pkgver}.tar.xz" "${pkgname}-lrelease.patch")
cksums=("SKIP" "SKIP")

prepare() {
    cd "${pkgname}-${pkgver}"
    patch -Np1 -i ../${pkgname}-lrelease.patch
    mkdir build
    cd build/
    cmake -DCMAKE_PREFIX_PATH="/usr/lib/cmake/Qt6" -DINSTALL_BINDIR=/usr/qt6/bin -Dudev=ON ..
}

build() {
  cd "${pkgname}-${pkgver}/build"
  make
}

package() {
  cd "${pkgname}-${pkgver}"/build
  make DESTDIR="${pkgdir}" install
}