File PKGBUILD of Package qlcplus5-git

# Maintainer: Nils Czernia <nils[at]czserver.de>
# modified for Open Build Service: Edgar Aichinger <edogawa@aon.at>

pkgname=qlcplus5-git
pkgver=5.1.1+git.20251006.b91bf2ffd
pkgrel=0
pkgdesc="Q Light Controller Plus - The open DMX lighting desk software for controlling professional lighting fixtures."
arch=('x86_64' 'armv7h')
url="http://qlcplus.org/"
license=('APACHE')
depends=('qt6-declarative' 'qt6-multimedia' 'qt6-serialport' 'qt6-svg' 'qt6-websockets' 'qt6-3d' 'libftdi-compat' 'libsndfile' 'fftw')
makedepends=('tar' 'qt6-tools' 'cmake' 'shared-mime-info' 'desktop-file-utils')
optdepends=('ola: Open Lighting Architecture plugin')
conflicts=('qlc' 'qlc-svn')
install=${pkgname}.install
source=("${pkgname}-${pkgver}.tar.xz" "${pkgname}-lrelease.patch")
cksums=("SKIP" "SKIP")

prepare() {
    cd "${pkgname}-${pkgver}"
    patch -Np1 -i ../${pkgname}-lrelease.patch
    mkdir build
    cd build/
    cmake -DCMAKE_PREFIX_PATH="/usr/lib/cmake" -Dqmlui=ON ..
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}/build"
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/build"
  make DESTDIR="${pkgdir}" install
}