File PKGBUILD of Package amarok-git

# Maintainer: Mihkel Tõnnov <mihhkel-at-gmail-dot-com>
# Contributor: Rhinoceros <https://aur.archlinux.org/account/rhinoceros>
# Contributor: Evert Vorster <evorster-at-gmail-dot-com>
# Contributor: Luca Weiss <luca (at) z3ntu (dot) xyz>
# Contributor: Jakub Schmidtke <sjakub-at-gmail-dot-com>
# Contributor: Maël Kerbiriou <mael.kerbiriou-at-free-dot-fr>


pkgbase=amarok-git
pkgname=(amarok-qt5-git amarok-qt6-git)
pkgver=2.9.71.r377.g9d74990
pkgrel=1
pkgdesc="The powerful music player for KDE"
arch=(x86_64)
url="http://amarok.kde.org"
license=("GPL2" "LGPL2.1" "FDL")

depends=(
ffmpeg
fftw
libmariadbclient
libofa
loudmouth
mariadb
taglib
)

makedepends=(
kdnssd5
kirigami2
knewstuff5
ktexteditor5
liblastfm-qt5
phonon-qt5
qt5-declarative
qt5-script
qt5-webengine
threadweaver5
kcmutils5

kdnssd
kirigami
knewstuff
kstatusnotifieritem
ktexteditor
ktextwidgets
phonon-qt6
qt6-declarative
qt6-webengine
threadweaver
kcmutils

extra-cmake-modules
gdk-pixbuf2
git
kdoctools
kdoctools5
knotifyconfig
knotifyconfig5
libgpod
libmtp
libmygpo-qt5
loudmouth
qt5-tools
qt6-tools
)

_optdepends=("libmtp: support for portable media devices"
             "ifuse: support for Apple iPod Touch and iPhone"
             "libgpod: support for Apple iPod audio devices"
             "loudmouth: backend needed by mp3tunes for syncing"
             "gmock: tests")
#"taglib-extras: taglib plugins for Audible and RealMedia files"
conflicts=("amarok")
provides=("amarok")
options=(!debug !lto)
source=("${pkgbase}-${pkgver}.tar.xz")
md5sums=('SKIP')

prepare() {
    mkdir -p "${srcdir}"/build-qt{5,6}
}

build() {
    local _conf=(-DCMAKE_INSTALL_PREFIX=/usr \
            -DCMAKE_INSTALL_LIBDIR=lib \
            -DBUILD_TESTING=OFF \
            -DCMAKE_BUILD_TYPE=Release
            )

    echo "Prepare Qt5..."
    cmake -B build-qt5 -S ${pkgbase}-${pkgver} \
        -DBUILD_WITH_QT6=OFF \
        "${_conf[@]:?_conf unset}"

    echo "Prepare Qt6..."
    cmake -B build-qt6 -S ${pkgbase}-${pkgver} \
        -DBUILD_WITH_QT6=ON \
        -DWITH_GPODDER=OFF \
        -DWITH_IPOD=OFF \
        -DWITH_LASTFM=OFF \
        "${_conf[@]:?_conf unset}"

    echo "Building Qt5..."
    cmake --build build-qt5 -j 8
    echo "Building Qt6..."
    cmake --build build-qt6 -j 8
}

package_amarok-qt5-git(){
    depends+=(
              kdnssd5
              kirigami2
              knewstuff5
              ktexteditor5
              liblastfm-qt5
              phonon-qt5
              qt5-declarative
              qt5-script
              qt5-webengine
              threadweaver5
              kcmutils5
              )
    optdepends=("${_optdepends[@]}"
                "libmygpo-qt5: gpodder.net Internet Service")
    provides+=("${pkgname%-*}")
    conflicts+=(amarok-qt6)

    DESTDIR="$pkgdir" cmake --install build-qt5
}

package_amarok-qt6-git(){
    depends+=(
              kdnssd
              kirigami
              knewstuff
              kstatusnotifieritem
              ktexteditor
              ktextwidgets
              phonon-qt6
              qt6-declarative
              qt6-webengine
              threadweaver
              kcmutils
              )
    optdepends=("${_optdepends[@]}")
    provides+=("${pkgname%-*}")
    conflicts+=(amarok-qt5)

    DESTDIR="$pkgdir" cmake --install build-qt6
}