File PKGBUILD of Package mpv-build-git

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package mpv-build-git (Revision 6b164ddf16b92feb618306accd39fdf0)

Currently displaying revision 6b164ddf16b92feb618306accd39fdf0 , Show latest

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=mpv-build-git
pkgver=v0.27.0.548.g3c4667c862
pkgrel=1
pkgdesc="Video player based on MPlayer/mplayer2 (uses statically linked ffmpeg). (GIT version)"
arch=('x86_64')
depends=(
         'libfribidi.so'
         'gnutls'
         'libjack.so'
         'liblcms2.so'
         'libarchive.so'
         'libbluray.so'
         'libbs2b.so'
         'libcaca'
         'libcdio-paranoia'
         'libdav1d.so'
         'libdvdnav'
         'libgme'
         'libmysofa'
         'libplacebo.so'
         'libpulse.so'
         'libshaderc_shared.so'
         'libsixel'
         'libsoxr'
         'libssh.so'
         'libva.so'
         'libvdpau'
         'libxinerama'
         'libxkbcommon'
         'libxrandr'
         'libxss'
         'libxv'
         'luajit'
         'mujs'
         'libopenal.so'
         'libxpresent'
         'rubberband'
         'sdl2'
         'sndio'
         'uchardet'
         'v4l-utils'
         'libvulkan.so'
         'wayland'
         'spirv-cross'
         'zimg'
         'libpipewire-0.3.so'
         'davs2'
         )
license=('GPL2' 'GPL3' 'LGPL3' 'LGPL2.1' 'BSD')
url='http://mpv.io'
makedepends=(
             'git'
             'python-docutils'
             'nasm'
             'ladspa'
             'fontconfig'
             'vulkan-headers'
             'vulkan-validation-layers'
             'wayland-protocols'
             'ffnvcodec-headers'
             'clang'
             )
optdepends=(
            'mpv-bash-completion: Additional completion definitions for Bash users'
            'nvidia-utils: for hardware accelerated video decoding with CUDA'
            'yt-dlp: for video-sharing websites playback'
            'youtube-dl: for video-sharing websites playback'
            'zsh-completions: Additional completion definitions for Zsh users'
            )
provides=('mpv' 'libmpv.so')
conflicts=('mpv' 'libmpv.so')
options=('!emptydirs')
source=("mpv-build.tar.xz"
        "mpv-${pkgver}.tar.xz"
        "ffmpeg-git.tar.xz"
        "libass-git.tar.xz"
        'https://waf.io/waf-2.0.20')
sha512sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP')
backup=('etc/mpv/encoding-profiles.conf')

if [ -f /usr/lib/libvapoursynth.so ]; then
  depends+=('vapoursynth')
fi
if [ -f /usr/lib/libavisynth.so.*.*.* ]; then
  depends+=('avisynthplus')
fi

prepare() {
  cd mpv-build
  ln -s "${srcdir}/mpv-${pkgver}" ./mpv
  ln -s "${srcdir}/ffmpeg-git" ./ffmpeg
  ln -s "${srcdir}/libass-git" ./libass
  install -m755 "${srcdir}"/waf-2.0.20 ./mpv/waf

# Set ffmpeg/libass/mpv flags
  _ffmpeg_options=(
    '--disable-programs'
    '--enable-ladspa'
    '--enable-libbs2b'
    '--enable-libdav1d'
    '--enable-libgme'
    '--enable-libmysofa'
    '--enable-libsoxr'
    '--enable-libssh'
    '--enable-libjack'
    '--enable-libpulse'
    '--enable-libdavs2'
    '--enable-nonfree'
    '--enable-cuda'
    )
if [ -f /usr/lib/libavisynth.so.*.*.* ]; then
  _ffmpeg_options+=('--enable-avisynth')
fi
if [ -f /usr/lib/libvapoursynth.so ]; then
  _ffmpeg_options+=('--enable-vapoursynth')
fi
  _mpv_options=(
    '--prefix=/usr'
    '--confdir=/etc/mpv'
    '--htmldir=/usr/share/doc/mpv/html'
    '--disable-build-date'
    '--lua=luajit'
    '--enable-cdda'
    '--enable-dvbin'
    '--enable-dvdnav'
    '--enable-html-build'
    '--enable-libarchive'
    '--enable-libmpv-shared'
    '--enable-openal'
    '--enable-sdl2'
    '--enable-shaderc'
    '--enable-vulkan'
    '--enable-gl-x11'
    '--enable-egl'
    '--enable-egl-x11'
    '--enable-egl-drm'
    '--enable-gl-wayland'
    '--enable-drm'
    '--enable-gbm'
    '--enable-wayland-scanner'
    '--enable-wayland-protocols'
    '--enable-wayland'
    '--enable-vdpau'
    '--enable-vdpau-gl-x11'
    '--enable-vaapi'
    '--enable-vaapi-x11'
    '--enable-vaapi-wayland'
    '--enable-vaapi-drm'
    '--enable-vaapi-x-egl'
    '--enable-cuda-hwaccel'
    '--enable-cuda-interop'
    '--color=yes'
    )

(IFS=$'\n'; echo "${_ffmpeg_options[*]}" > ffmpeg_options )
  (IFS=$'\n'; echo "${_mpv_options[*]}" > mpv_options )

#cd ./source/mpv
  #./bootstrap.py
}

build() {
  cd mpv-build
  ./build
}

package() {
  cd mpv-build
  DESTDIR="${pkgdir}" ./install

install -Dm755 ./mpv/TOOLS/mpv_identify.sh "${pkgdir}/usr/bin/mpv-identify"
  install -Dm755 ./mpv/TOOLS/idet.sh "${pkgdir}/usr/bin/mpv-idet"
  install -Dm755 ./mpv/TOOLS/umpv "${pkgdir}/usr/bin/umpv"

install -Dm644 ./mpv/DOCS/encoding.rst "${pkgdir}/usr/share/doc/mpv/encoding.rst"
  install -Dm644 ./mpv/DOCS/edl-mpv.rst "${pkgdir}/usr/share/doc/mpv/edl-mpv.rst"
  install -Dm644 ./mpv/DOCS/client-api-changes.rst "${pkgdir}/usr/share/doc/mpv/client-api-changes.rst"
  install -Dm644 ./mpv/DOCS/contribute.md "${pkgdir}/usr/share/doc/mpv/contribute.md"

sed 's|/usr/local/etc/mpv.conf|/etc/mpv.conf|g' -i "${pkgdir}/usr/share/doc/mpv/mpv.conf"

(cd ./mpv/TOOLS/lua; for i in $(find . -type f); do install -Dm644 "${i}" "${pkgdir}/usr/share/mpv/scripts/${i}"; done)

install -Dm644 mpv/LICENSE.GPL "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.GPL"
  install -Dm644 mpv/LICENSE.GPL "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.LGPL"
}

Places

File PKGBUILD of Package mpv-build-git (Revision 6b164ddf16b92feb618306accd39fdf0)

Places