File _service:set_version:PKGBUILD of Package skympc-git

# Maintainer: Josip Ponjavic <josipponjavic at gmail dot com>

pkgname=skympc-git
pkgver=20170612.071be65
pkgrel=0
pkgdesc="A simple MPD (Music Player Daemon) client, powerd by Qt"
arch=('i686' 'x86_64')
url="http://www.soramimi.jp/skympc/index.html"
license=('GPL3')
depends=('hicolor-icon-theme' 'mpd' 'qt5-svg')
makedepends=('git' 'ruby')
provides=('skympc')
conflicts=('skympc')
source=("${pkgname}-${pkgver}.tar.xz"
        'use-system-fonts-on-linux.patch')
sha256sums=('SKIP'
            '7c21787bbdc3882594d2cbf6bb8f74820e1a74c2527058c773bca53786a8ee79')

prepare() {
  cd "${pkgname}-${pkgver}"
  patch -p1 -i ../use-system-fonts-on-linux.patch
}

build() {
  cd "${pkgname}-${pkgver}"
  qmake-qt5
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  install -Dm755 SkyMPC "${pkgdir}/usr/bin/SkyMPC"
  install -Dm644 image/appicon.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/SkyMPC.svg"
  install -Dm644 image/appicon.png "$pkgdir/usr/share/icons/hicolor/32x32/apps/SkyMPC.png"
  install -Dm644 LinuxDesktop/SkyMPC.desktop "${pkgdir}/usr/share/applications/SkyMPC.desktop"
  sed -i 's|Exec=/opt/SkyMPC/SkyMPC|Exec=SkyMPC|' "${pkgdir}/usr/share/applications/SkyMPC.desktop"
  sed -i 's|Icon=/opt/SkyMPC/SkyMPC.svg|Icon=SkyMPC|' "${pkgdir}/usr/share/applications/SkyMPC.desktop"
  echo 'Categories=Qt;AudioVideo;Audio;Player;' >> "${pkgdir}/usr/share/applications/SkyMPC.desktop"
}