File PKGBUILD of Package xfce4-session

# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: tobias <tobias funnychar archlinux.org>

pkgname=xfce4-session
pkgver=4.16.0
pkgrel=1
pkgdesc="Session manager for Xfce"
arch=('x86_64')
url="https://docs.xfce.org/xfce/xfce4-session/start"
license=('GPL2')
groups=('xfce4')
depends=('libxfce4ui' 'libxfce4windowing' 'libwnck3' 'xfconf' 'libsm' 'polkit' 'xorg-iceauth'
         'xorg-xinit' 'xorg-xrdb' 'polkit-gnome' 'hicolor-icon-theme')
makedepends=('git' 'xfce4-dev-tools')
optdepends=('gnome-keyring: for keyring support when GNOME compatibility is enabled'
            'xfce4-screensaver: for locking screen with xflock4'
            'xscreensaver: for locking screen with xflock4'
            'gnome-screensaver: for locking screen with xflock4'
            'xlockmore: for locking screen with xflock4'
            'slock: for locking screen with xflock4')
source=("${pkgname}-${pkgver}.tar.xz"
        source-system-xinitrc-scripts.patch
        xfce-polkit-gnome-authentication-agent-1.desktop)
sha512sums=('SKIP'
            '1e5dae81dd95f8adf8e6e99852d59790ae0a5fb5faea3d23edac8aae1d0f538a39cf58a1e33b6d322f9bf1dcc87cb86213d28abde48b4efaae6ca58ecca8d04e'
            '1b2f9d21d7f93e619dc6762e54e2418786d5999f303d54f24789e0adb93808c5da75e6e2824eb50d12261090facada60d7bd351296546160940e7c5f7173e4b1')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  # https://bugzilla.xfce.org/show_bug.cgi?id=15440
  #patch -Np1 -i ../source-system-xinitrc-scripts.patch
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./autogen.sh \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --disable-debug \
    --enable-systemd
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="${pkgdir}" install

  # Provide a default PolicyKit Authentication Agent (FS#42569)
  install -d "${pkgdir}"/etc/xdg/autostart
  cp "${srcdir}"/xfce-polkit-gnome-authentication-agent-1.desktop \
    "${pkgdir}"/etc/xdg/autostart/
}

# vim:set ts=2 sw=2 et: