File PKGBUILD of Package xfce4-settings

# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: tobias <tobias funnychar archlinux.org>
# Contributor: Corrado Primier <bardo@aur.archlinux.org>

pkgname=xfce4-settings
pkgver=4.16.2
pkgrel=1
pkgdesc="Settings manager of the Xfce desktop"
arch=('x86_64')
url="https://docs.xfce.org/xfce/xfce4-settings/start"
license=('GPL2')
groups=('xfce4')
depends=('exo' 'garcon' 'libxfce4ui' 'xfconf' 'libnotify' 'libcanberra'
         'colord' 'libxklavier' 'adwaita-icon-theme' 'gnome-themes-extra')
makedepends=('git' 'xf86-input-libinput' 'xfce4-dev-tools')
optdepends=('python: xfce4-compose-mail -- "mailto:" URI handling')
source=("${pkgname}-${pkgver}.tar.xz"
        'enable-antialias-by-default.patch')
sha512sums=('SKIP'
            'f65e9e153f1c06b6ca200bfd6f6eccde21674233bcb36065377fc6d51ecdedc679b99fb186b04c5c94bde46b9e4d7b981d3366f99532f7c99b5e80400a3bfa87')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  # Enable font hinting by default
  patch -uNp2 -r- -i ../enable-antialias-by-default.patch
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./autogen.sh \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --enable-xrandr \
    --enable-xcursor \
    --enable-libnotify \
    --enable-libxklavier \
    --enable-pluggable-dialogs \
    --enable-sound-settings \
    --disable-debug
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: