File 0001-CMake-improvements.patch of Package mingw64-sdr-j-dabreceiver

Overview Repositories Revisions Requests Users Attributes Meta

File 0001-CMake-improvements.patch of Package mingw64-sdr-j-dabreceiver (Revision aaefb0aa6475a041552f40fc69373bc7)

Currently displaying revision aaefb0aa6475a041552f40fc69373bc7 , Show latest

From 5972aba13bdea7985e3aadd4c5d5c4c3cec19063 Mon Sep 17 00:00:00 2001
From: Martin Hauke <mardnh@gmx.de>
Date: Fri, 18 Mar 2016 23:00:46 +0100
Subject: [PATCH] CMake improvements

---
 CMakeLists.txt                     | 208 +++++++++++--------------------------
 cmake/Modules/FindFFTW3f.cmake     |  41 ++++++++
 cmake/Modules/FindFaad.cmake       |  34 ++++++
 cmake/Modules/FindLibAIRSPY.cmake  |  28 +++++
 cmake/Modules/FindLibRTLSDR.cmake  |  28 +++++
 cmake/Modules/FindLibSndFile.cmake |  20 ++++
 cmake/Modules/FindPortaudio.cmake  |  52 ++++++++++
 cmake/Modules/FindQwt.cmake        |  64 ++++++++++++
 src/input/airspy/airspy-handler.h  |   2 +-
 9 files changed, 331 insertions(+), 146 deletions(-)
 create mode 100644 cmake/Modules/FindFFTW3f.cmake
 create mode 100644 cmake/Modules/FindFaad.cmake
 create mode 100644 cmake/Modules/FindLibAIRSPY.cmake
 create mode 100644 cmake/Modules/FindLibRTLSDR.cmake
 create mode 100644 cmake/Modules/FindLibSndFile.cmake
 create mode 100644 cmake/Modules/FindPortaudio.cmake
 create mode 100644 cmake/Modules/FindQwt.cmake

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 4f72dbc..1abefa0 100755
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -1,8 +1,25 @@
 cmake_minimum_required( VERSION 2.8.11 )
-set (CMAKE_BUILD_TYPE Release )
 set (objectName sdr-j-dabreceiver-0.993)
 set ( CMAKE_INSTALL_PREFIX . )
 add_definitions ( -Wall)
+
+if(MINGW)
+    add_definitions ( -municode)
+endif()
+
+########################################################################
+# select the release build type by default to get optimization flags
+########################################################################
+if(NOT CMAKE_BUILD_TYPE)
+   set(CMAKE_BUILD_TYPE "Release")
+   message(STATUS "Build type not specified: defaulting to release.")
+endif(NOT CMAKE_BUILD_TYPE)
+set(CMAKE_BUILD_TYPE ${CMAKE_BUILD_TYPE} CACHE STRING "")
+
+### make sure our local CMake Modules path comes first
+list(INSERT CMAKE_MODULE_PATH 0 ${CMAKE_SOURCE_DIR}/cmake/Modules)
+
+
 ######################################################################
 #       R E A D  T H I S
 #####################################################################
@@ -23,6 +40,9 @@ add_definitions ( -Wall)
 #	add_definitions (-DMOT_BASICS__) 	# use at your own risk
 #	add_definitions (-DMSC_DATA__)		# use at your own risk
 ########################################################################
+
+	find_package (PkgConfig)
+
 	find_package (Qt5Core REQUIRED)
 	find_package (Qt5Widgets REQUIRED)
 	find_package (Qt5Network REQUIRED)
@@ -31,112 +51,34 @@ add_definitions ( -Wall)
 	include_directories (
 	      ${Qt5Network_INCLUDE_DIRS}
 	)
-	find_library (DYNAMIC_LOAD dl)
-	if(NOT(DYNAMIC_LOAD))
-	   message(FATAL_ERROR "please install -ldl")
-	else(NOT(DYNAMIC_LOAD))
-	   set(extraLibs ${DYNAMIC_LOAD})
-	endif(NOT(DYNAMIC_LOAD))
-#
 
-#	find_library(QWT qwt)
-	if (QWT_INCLUDE_DIRS)
-#	Already in cache, be silent
-	   set (QWT_FIND_QUIETLY TRUE)
-	endif (QWT_INCLUDE_DIRS)
-
-	find_path (QWT_INCLUDE_DIR
-	           NAMES qwt_plot.h
-	           PATHS
-	           /usr/local/include/qwt-qt5
-	           /usr/local/include/qwt
-	           /usr/local/include/qwt6
-	           /usr/include/qwt6
-	           /usr/include/qwt
-	)
+        find_package(Qwt)
+        if (NOT QWT_FOUND)
+            message(FATAL_ERROR "please install qwt library")
+        endif ()
 
-	list (APPEND QWT_INCLUDE_DIRS ${QWT_INCLUDE_DIR} )
-	find_library (QWT_LIBRARIES
-	              NAMES qwt-qt5 qwt qwt6
-#	              PATHS /usr/local/lib /usr/lib
-                      PATH_SUFFIXES lib64 Lib64 lib Lib
-	)
+        find_package(FFTW3f)
+        if (NOT FFTW3F_FOUND)
+            message(FATAL_ERROR "please install FFTW3")
+        endif ()
 
-#	message (STATUS ${QWT_LIBRARIES} ${QWT_INCLUDE_DIRS})
-#	handle the QUIETLY and REQUIRED arguments and set QWT_FOUND to TRUE if 
-#	all listed variables are TRUE
-	include (FindPackageHandleStandardArgs)
-	find_package_handle_standard_args (
-	                     Qwt DEFAULT_MSG QWT_LIBRARIES QWT_INCLUDE_DIRS )
-	MARK_AS_ADVANCED (QWT_LIBRARIES QWT_INCLUDE_DIRS)
-#	Find_Package(PkgConfig)
-#	pkg_check_modules(FFTW fftw3f REQUIRED)
-#	link_directories(${FFTW_INCLUDE_DIRS})
-#	Find the native FFTW includes and library
-#
-#	FFTW_INCLUDES    - where to find fftw3f.h
-#	FFTW_LIBRARIES   - List of libraries when using FFTW.
-#	FFTW_FOUND       - True if FFTW found.
-
-	if (FFTW_INCLUDE_DIRS)
-#	Already in cache, be silent
-	   set (FFTW_FIND_QUIETLY TRUE)
-	endif (FFTW_INCLUDE_DIRS)
-
-	find_path (FFTW_INCLUDE_DIR fftw3.h
-	           HINTS
-                   ENV FFTW_ROOT
-                   PATHS 
-	           PATH_SUFFIXES
-	           include
-	           Include
-	)
+        find_package(Portaudio)
+        if (NOT PORTAUDIO_FOUND)
+            message(FATAL_ERROR "please install portaudio V19")
+        endif ()
+        list(APPEND extraLibs ${PORTAUDIO_LIBRARIES})
+
+        find_package(Faad)
+        if (NOT FAAD_FOUND )
+            message(FATAL_ERROR "please install libfaad")
+        endif ()
+
+        find_package(LibSndFile)
+        if (NOT LIBSNDFILE_FOUND)
+            message(FATAL_ERROR "please install libsndfile")
+        endif ()
+        list(APPEND extraLibs ${LIBSNDFILE_LIBRARY})
 
-	list (APPEND FFTW_INCLUDE_DIRS ${FFTW_INCLUDE_DIR})
-	find_library (FFTW_LIBRARIES NAMES fftw3f
-                      HINTS ENV FFTW_ROOT
-                      PATHS
-                      PATH_SUFFIXES lib64 Lib64 lib Lib)
-
-	message (STATUS ${FFTW_LIBRARIES} ${FFTW_INCLUDE_DIRS})
-#	handle the QUIETLY and REQUIRED arguments and set FFTW_FOUND to TRUE if
-#	all listed variables are TRUE
-
-	include (FindPackageHandleStandardArgs)
-	find_package_handle_standard_args (
-	                  FFTW DEFAULT_MSG FFTW_LIBRARIES FFTW_INCLUDE_DIRS)
-	mark_as_advanced (FFTW_LIBRARIES FFTW_INCLUDE_DIRS)
-
-	Find_Package (PkgConfig)
-	find_library (FAAD faad)
-	if (NOT(FAAD))
-	   message(FATAL_ERROR "please install libfaad")
-	else (NOT(FAAD))
-	set (extraLibs  ${extraLibs} ${FAAD})
-	endif(NOT(FAAD))
-
-	find_library (PORTAUDIO portaudio)
-	if (NOT(PORTAUDIO))
-	   message(FATAL_ERROR "please install portaudio V19")
-	else(NOT(PORTAUDIO))
-	   set (extraLibs  ${extraLibs} ${PORTAUDIO})
-	endif(NOT(PORTAUDIO))
-
-	SET (CMAKE_FIND_LIBRARY_SUFFIXES .so .a)
-
-	find_library (USB1 usb-1.0 HINTS /usr/lib)
-	if (NOT(USB1))
-	   message (FATAL_ERROR "please install libusb-1.0")
-	else(NOT(USB1))
-	   set(extraLibs ${extraLibs} ${USB1})
-	endif(NOT(USB1))
-
-	find_library (SNDFILE sndfile)
-	if (NOT(SNDFILE))
-	   message (FATAL_ERROR "please install libsndfile")
-	else (NOT(SNDFILE))
-	   set (extraLibs ${extraLibs} ${SNDFILE})
-	endif (NOT(SNDFILE))
 
 	find_library (PTHREADS pthread)
 	if (NOT(PTHREADS))
@@ -178,7 +120,6 @@ add_definitions ( -Wall)
 	           ./src/input
 	           ./src/input/rawfiles
 	           ./src/input/wavfiles
-	           /usr/include/
 	)
 
 	set (${objectName}_HDRS
@@ -328,19 +269,11 @@ add_definitions ( -Wall)
 	endif (SDRPLAY)
 
 	if (AIRSPY)
-	   find_library (AIRSPY_LIB airspy)
-	   if (NOT(AIRSPY_LIB))
-	      message (FATAL_ERROR "please install airspy library")
-	   else (NOT(AIRSPY_LIB))
-	      set (extraLibs ${extraLibs} ${AIRSPY_LIB})
-	   endif()
-	   find_path (AIRSPYLIB_INCLUDE_DIR
-	              NAMES airspy.h
-	              PATHS
-	              /usr/local/include/
-	              /usr/local/include/libairspy
-	   )
-	   include_directories (${AIRSPYLIB_INCLUDE_DIR})
+           find_package(LibAIRSPY)
+           if (NOT LIBAIRSPY_FOUND)
+               message(FATAL_ERROR "please install airspy library")
+           endif ()
+	   ### include_directories (${AIRSPYLIB_INCLUDE_DIR})
 
 	   set (${objectName}_UIS
 	        ${${objectName}_UIS}
@@ -370,19 +303,11 @@ add_definitions ( -Wall)
 	endif (AIRSPY)
 
 	if (DABSTICK_NEW)
-	   find_library (RTLSDR rtlsdr)
-	   if (NOT(RTLSDR))
-	      message (FATAL_ERROR "please install librtlsdr")
-	   else (NOT(RTLSDR))
-	      set (extraLibs ${extraLibs} ${RTLSDR})
-	   endif()
-	   find_path (DABSTICK_INCLUDE_DIR
-	              NAMES rtl-sdr.h
-	              PATHS
-	              /usr/local/include/
-	              /usr/include/
-	   )
-	   include_directories (${RTLSDR_INCLUDE_DIR})
+           find_package(LibRTLSDR)
+           if (NOT LIBRTLSDR_FOUND)
+               message(FATAL_ERROR "please install librtlsdr")
+           endif ()
+	   ###include_directories (${RTLSDR_INCLUDE_DIR})
 
 	   set (${objectName}_UIS
 	        ${${objectName}_UIS}
@@ -415,19 +340,11 @@ add_definitions ( -Wall)
 	endif()
 #
 	if (DABSTICK_OSMO)
-	   find_library (RTLSDR rtlsdr)
-	   if (NOT(RTLSDR))
-	      message (FATAL_ERROR "please install librtlsdr")
-	   else (NOT(RTLSDR))
-	      set (extraLibs ${extraLibs} ${RTLSDR})
-	   endif()
-	   find_path (DABSTICK_INCLUDE_DIR
-	              NAMES rtl-sdr.h
-	              PATHS
-	              /usr/local/include/
-	              /usr/include/
-	   )
-	   include_directories (${RTLSDR_INCLUDE_DIR})
+           find_package(LibRTLSDR)
+           if (NOT LIBRTLSDR_FOUND)
+               message(FATAL_ERROR "please install librtlsdr")
+           endif ()
+	   ###include_directories (${RTLSDR_INCLUDE_DIR})
 
 	   set (${objectName}_UIS
 	        ${${objectName}_UIS}
@@ -528,8 +445,8 @@ add_definitions ( -Wall)
 	          ${QT5Widgets_INCLUDES}
 	          ${QT_QTCORE_INCLUDE_DIR}
 	          ${QT_QTGUI_INCLUDE_DIR}
-	          ${QWT_INCLUDE_DIRS}
 	          ${FFTW_INCLUDE_DIRS}
+	          ${QWT_INCLUDE_DIRS}
 	          ${PORTAUDIO_INCLUDE_DIRS}
 	          ${FAAD_INCLUDE_DIRS}
 	          ${SNDFILES_INCLUDE_DIRS}
@@ -547,10 +464,11 @@ add_definitions ( -Wall)
 	                       Qt5::Widgets
 	                       Qt5::Network
 	                       ${RTLTCP_lib}
-	                       ${FFTW_LIBRARIES}
+	                       ${FFTW3F_LIBRARIES}
 	                       ${extraLibs}
 	                       ${FAAD_LIBRARIES}
 	                       ${QWT_LIBRARIES}
+	                       ${CMAKE_DL_LIBS}
 	)
 
 	INSTALL (TARGETS ${objectName} DESTINATION ../linux-bin)
diff --git a/cmake/Modules/FindFFTW3f.cmake b/cmake/Modules/FindFFTW3f.cmake
new file mode 100644
index 0000000..0ee7e46
--- /dev/null
+++ b/cmake/Modules/FindFFTW3f.cmake
@@ -0,0 +1,41 @@
+# http://tim.klingt.org/code/projects/supernova/repository/revisions/d336dd6f400e381bcfd720e96139656de0c53b6a/entry/cmake_modules/FindFFTW3f.cmake
+# Modified to use pkg config and use standard var names
+
+# Find single-precision (float) version of FFTW3
+
+INCLUDE(FindPkgConfig)
+PKG_CHECK_MODULES(PC_FFTW3F "fftw3f >= 3.0")
+
+FIND_PATH(
+    FFTW3F_INCLUDE_DIRS
+    NAMES fftw3.h
+    HINTS $ENV{FFTW3_DIR}/include
+        ${PC_FFTW3F_INCLUDE_DIR}
+    PATHS /usr/local/include
+          /usr/include
+)
+
+FIND_LIBRARY(
+    FFTW3F_LIBRARIES
+    NAMES fftw3f libfftw3f
+    HINTS $ENV{FFTW3_DIR}/lib
+        ${PC_FFTW3F_LIBDIR}
+    PATHS /usr/local/lib
+          /usr/lib
+          /usr/lib64
+)
+
+FIND_LIBRARY(
+    FFTW3F_THREADS_LIBRARIES
+    NAMES fftw3f_threads libfftw3f_threads
+    HINTS $ENV{FFTW3_DIR}/lib
+        ${PC_FFTW3F_LIBDIR}
+    PATHS /usr/local/lib
+          /usr/lib
+          /usr/lib64
+)
+
+
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(FFTW3F DEFAULT_MSG FFTW3F_LIBRARIES FFTW3F_INCLUDE_DIRS)
+MARK_AS_ADVANCED(FFTW3F_LIBRARIES FFTW3F_INCLUDE_DIRS FFTW3F_THREADS_LIBRARIES)
\ No newline at end of file
diff --git a/cmake/Modules/FindFaad.cmake b/cmake/Modules/FindFaad.cmake
new file mode 100644
index 0000000..541861a
--- /dev/null
+++ b/cmake/Modules/FindFaad.cmake
@@ -0,0 +1,34 @@
+# Try to find FAAD library and include path.
+# Once done this will define
+#
+# FAAD_INCLUDE_DIRS - where to find faad.h, etc.
+# FAAD_LIBRARIES - List of libraries when using libfaad.
+# FAAD_FOUND - True if libfaad found.
+
+find_path(FAAD_INCLUDE_DIR faad.h DOC "The directory where faad.h resides")
+find_library(FAAD_LIBRARY NAMES faad DOC "The libfaad library")
+
+if(FAAD_INCLUDE_DIR AND FAAD_LIBRARY)
+  set(FAAD_FOUND 1)
+  set(FAAD_LIBRARIES ${FAAD_LIBRARY})
+  set(FAAD_INCLUDE_DIRS ${FAAD_INCLUDE_DIR})
+else(FAAD_INCLUDE_DIR AND FAAD_LIBRARY)
+  set(FAAD_FOUND 0)
+  set(FAAD_LIBRARIES)
+  set(FAAD_INCLUDE_DIRS)
+endif(FAAD_INCLUDE_DIR AND FAAD_LIBRARY)
+
+mark_as_advanced(FAAD_INCLUDE_DIR)
+mark_as_advanced(FAAD_LIBRARY)
+mark_as_advanced(FAAD_FOUND)
+
+if(NOT FAAD_FOUND)
+  set(FAAD_DIR_MESSAGE "libfaad was not found. Make sure FAAD_LIBRARY and FAAD_INCLUDE_DIR are set.")
+  if(NOT FAAD_FIND_QUIETLY)
+    message(STATUS "${FAAD_DIR_MESSAGE}")
+  else(NOT FAAD_FIND_QUIETLY)
+    if(FAAD_FIND_REQUIRED)
+      message(FATAL_ERROR "${FAAD_DIR_MESSAGE}")
+    endif(FAAD_FIND_REQUIRED)
+  endif(NOT FAAD_FIND_QUIETLY)
+endif(NOT FAAD_FOUND)
diff --git a/cmake/Modules/FindLibAIRSPY.cmake b/cmake/Modules/FindLibAIRSPY.cmake
new file mode 100644
index 0000000..2402f2f
--- /dev/null
+++ b/cmake/Modules/FindLibAIRSPY.cmake
@@ -0,0 +1,28 @@
+if(NOT LIBAIRSPY_FOUND)
+
+  pkg_check_modules (LIBAIRSPY_PKG libairspy)
+  find_path(LIBAIRSPY_INCLUDE_DIR NAMES libairspy/airspy.h
+    PATHS
+    ${LIBAIRSPY_PKG_INCLUDE_DIRS}
+    /usr/include
+    /usr/local/include
+  )
+
+  find_library(LIBAIRSPY_LIBRARIES NAMES airspy
+    PATHS
+    ${LIBAIRSPY_PKG_LIBRARY_DIRS}
+    /usr/lib
+    /usr/local/lib
+  )
+
+  if(LIBAIRSPY_INCLUDE_DIR AND LIBAIRSPY_LIBRARIES)
+    set(LIBAIRSPY_FOUND TRUE CACHE INTERNAL "libairspy found")
+    message(STATUS "Found libairspy: ${LIBAIRSPY_INCLUDE_DIR}, ${LIBAIRSPY_LIBRARIES}")
+  else(LIBAIRSPY_INCLUDE_DIR AND LIBAIRSPY_LIBRARIES)
+    set(LIBAIRSPY_FOUND FALSE CACHE INTERNAL "libairspy found")
+    message(STATUS "libairspy not found.")
+  endif(LIBAIRSPY_INCLUDE_DIR AND LIBAIRSPY_LIBRARIES)
+
+  mark_as_advanced(LIBAIRSPY_INCLUDE_DIR LIBAIRSPY_LIBRARIES)
+
+endif(NOT LIBAIRSPY_FOUND)
diff --git a/cmake/Modules/FindLibRTLSDR.cmake b/cmake/Modules/FindLibRTLSDR.cmake
new file mode 100644
index 0000000..25a1d05
--- /dev/null
+++ b/cmake/Modules/FindLibRTLSDR.cmake
@@ -0,0 +1,28 @@
+if(NOT LIBRTLSDR_FOUND)
+
+  pkg_check_modules (LIBRTLSDR_PKG librtlsdr)
+  find_path(LIBRTLSDR_INCLUDE_DIR NAMES rtl-sdr.h
+	PATHS
+	${LIBRTLSDR_PKG_INCLUDE_DIRS}
+	/usr/include
+	/usr/local/include
+  )
+
+  find_library(LIBRTLSDR_LIBRARIES NAMES rtlsdr
+	PATHS
+	${LIBRTLSDR_PKG_LIBRARY_DIRS}
+	/usr/lib
+	/usr/local/lib
+  )
+
+  if(LIBRTLSDR_INCLUDE_DIR AND LIBRTLSDR_LIBRARIES)
+	set(LIBRTLSDR_FOUND TRUE CACHE INTERNAL "librtlsdr found")
+	message(STATUS "Found librtlsdr: ${LIBRTLSDR_INCLUDE_DIR}, ${LIBRTLSDR_LIBRARIES}")
+  else(LIBRTLSDR_INCLUDE_DIR AND LIBRTLSDR_LIBRARIES)
+	set(LIBRTLSDR_FOUND FALSE CACHE INTERNAL "librtlsdr found")
+	message(STATUS "librtlsdr not found.")
+  endif(LIBRTLSDR_INCLUDE_DIR AND LIBRTLSDR_LIBRARIES)
+
+  mark_as_advanced(LIBRTLSDR_INCLUDE_DIR LIBRTLSDR_LIBRARIES)
+
+endif(NOT LIBRTLSDR_FOUND)
diff --git a/cmake/Modules/FindLibSndFile.cmake b/cmake/Modules/FindLibSndFile.cmake
new file mode 100644
index 0000000..cd28788
--- /dev/null
+++ b/cmake/Modules/FindLibSndFile.cmake
@@ -0,0 +1,20 @@
+# Find libsndfile
+
+FIND_PATH(LIBSNDFILE_INCLUDE_DIR sndfile.h)
+
+SET(LIBSNDFILE_NAMES ${LIBSNDFILE_NAMES} sndfile libsndfile)
+FIND_LIBRARY(LIBSNDFILE_LIBRARY NAMES ${LIBSNDFILE_NAMES} PATH)
+
+IF (LIBSNDFILE_INCLUDE_DIR AND LIBSNDFILE_LIBRARY)
+    SET(LIBSNDFILE_FOUND TRUE)
+ENDIF (LIBSNDFILE_INCLUDE_DIR AND LIBSNDFILE_LIBRARY)
+
+IF (LIBSNDFILE_FOUND)
+    IF (NOT LibSndFile_FIND_QUIETLY)
+        MESSAGE (STATUS "Found LibSndFile: ${LIBSNDFILE_LIBRARY}")
+    ENDIF (NOT LibSndFile_FIND_QUIETLY)
+ELSE (LIBSNDFILE_FOUND)
+    IF (LibSndFile_FIND_REQUIRED)
+        MESSAGE (FATAL_ERROR "Could not find sndfile")
+    ENDIF (LibSndFile_FIND_REQUIRED)
+ENDIF (LIBSNDFILE_FOUND)
diff --git a/cmake/Modules/FindPortaudio.cmake b/cmake/Modules/FindPortaudio.cmake
new file mode 100644
index 0000000..8aa17d4
--- /dev/null
+++ b/cmake/Modules/FindPortaudio.cmake
@@ -0,0 +1,52 @@
+# - Try to find Portaudio
+# Once done this will define
+#
+#  PORTAUDIO_FOUND - system has Portaudio
+#  PORTAUDIO_INCLUDE_DIRS - the Portaudio include directory
+#  PORTAUDIO_LIBRARIES - Link these to use Portaudio
+
+include(FindPkgConfig)
+pkg_check_modules(PC_PORTAUDIO portaudio-2.0)
+
+find_path(PORTAUDIO_INCLUDE_DIRS
+  NAMES
+    portaudio.h
+  PATHS
+      /usr/local/include
+      /usr/include
+  HINTS
+    ${PC_PORTAUDIO_INCLUDEDIR}
+)
+
+find_library(PORTAUDIO_LIBRARIES
+  NAMES
+    portaudio
+  PATHS
+      /usr/local/lib
+      /usr/lib
+      /usr/lib64
+  HINTS
+    ${PC_PORTAUDIO_LIBDIR}
+)
+
+mark_as_advanced(PORTAUDIO_INCLUDE_DIRS PORTAUDIO_LIBRARIES)
+
+# Found PORTAUDIO, but it may be version 18 which is not acceptable.
+if(EXISTS ${PORTAUDIO_INCLUDE_DIRS}/portaudio.h)
+  include(CheckCXXSourceCompiles)
+  set(CMAKE_REQUIRED_INCLUDES_SAVED ${CMAKE_REQUIRED_INCLUDES})
+  set(CMAKE_REQUIRED_INCLUDES ${PORTAUDIO_INCLUDE_DIRS})
+  CHECK_CXX_SOURCE_COMPILES(
+    "#include <portaudio.h>\nPaDeviceIndex pa_find_device_by_name(const char *name); int main () {return 0;}"
+    PORTAUDIO2_FOUND)
+  set(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES_SAVED})
+  unset(CMAKE_REQUIRED_INCLUDES_SAVED)
+  if(PORTAUDIO2_FOUND)
+    INCLUDE(FindPackageHandleStandardArgs)
+    FIND_PACKAGE_HANDLE_STANDARD_ARGS(PORTAUDIO DEFAULT_MSG PORTAUDIO_INCLUDE_DIRS PORTAUDIO_LIBRARIES)
+  else(PORTAUDIO2_FOUND)
+    message(STATUS
+      "  portaudio.h not compatible (requires API 2.0)")
+    set(PORTAUDIO_FOUND FALSE)
+  endif(PORTAUDIO2_FOUND)
+endif()
diff --git a/cmake/Modules/FindQwt.cmake b/cmake/Modules/FindQwt.cmake
new file mode 100644
index 0000000..5a91e83
--- /dev/null
+++ b/cmake/Modules/FindQwt.cmake
@@ -0,0 +1,64 @@
+# - try to find Qwt libraries and include files
+# QWT_INCLUDE_DIR where to find qwt_global.h, etc.
+# QWT_LIBRARIES libraries to link against
+# QWT_FOUND If false, do not try to use Qwt
+# qwt_global.h holds a string with the QWT version;
+#   test to make sure it's at least 5.2
+
+find_path(QWT_INCLUDE_DIRS
+  NAMES qwt_global.h
+  HINTS
+  ${CMAKE_INSTALL_PREFIX}/include/qwt
+  PATHS
+  /usr/local/include/qwt-qt4
+  /usr/local/include/qwt
+  /usr/include/qwt6
+  /usr/include/qwt-qt4
+  /usr/include/qwt-qt4
+  /usr/include/qwt
+  /usr/include/qwt5
+  /usr/include/qwt6-qt5
+  /opt/local/include/qwt
+  /sw/include/qwt
+  /usr/local/lib/qwt.framework/Headers
+)
+
+find_library (QWT_LIBRARIES
+  NAMES qwt6 qwt6-qt5 qwt-qt5 qwt6-qt4 qwt qwt-qt4
+  HINTS
+  ${CMAKE_INSTALL_PREFIX}/lib
+  ${CMAKE_INSTALL_PREFIX}/lib64
+  PATHS
+  /usr/local/lib
+  /usr/lib
+  /opt/local/lib
+  /sw/lib
+  /usr/local/lib/qwt.framework
+)
+
+set(QWT_FOUND FALSE)
+if(QWT_INCLUDE_DIRS)
+  file(STRINGS "${QWT_INCLUDE_DIRS}/qwt_global.h"
+    QWT_STRING_VERSION REGEX "QWT_VERSION_STR")
+  set(QWT_WRONG_VERSION True)
+  set(QWT_VERSION "No Version")
+  string(REGEX MATCH "[0-9]+.[0-9]+.[0-9]+" QWT_VERSION ${QWT_STRING_VERSION})
+  string(COMPARE LESS ${QWT_VERSION} "5.2.0" QWT_WRONG_VERSION)
+  string(COMPARE GREATER ${QWT_VERSION} "6.2.0" QWT_WRONG_VERSION)
+
+  message(STATUS "QWT Version: ${QWT_VERSION}")
+  if(NOT QWT_WRONG_VERSION)
+    set(QWT_FOUND TRUE)
+  else(NOT QWT_WRONG_VERSION)
+    message(STATUS "QWT Version must be >= 5.2 and <= 6.2.0, Found ${QWT_VERSION}")
+  endif(NOT QWT_WRONG_VERSION)
+
+endif(QWT_INCLUDE_DIRS)
+
+if(QWT_FOUND)
+  # handle the QUIETLY and REQUIRED arguments and set QWT_FOUND to TRUE if
+  # all listed variables are TRUE
+  include ( FindPackageHandleStandardArgs )
+  find_package_handle_standard_args( Qwt DEFAULT_MSG QWT_LIBRARIES QWT_INCLUDE_DIRS )
+  MARK_AS_ADVANCED(QWT_LIBRARIES QWT_INCLUDE_DIRS)
+endif(QWT_FOUND)
diff --git a/src/input/airspy/airspy-handler.h b/src/input/airspy/airspy-handler.h
index 52dcb02..7c21b7f 100755
--- a/src/input/airspy/airspy-handler.h
+++ b/src/input/airspy/airspy-handler.h
@@ -24,7 +24,7 @@
 #include	"ringbuffer.h"
 #include	"virtual-input.h"
 #include	"ui_airspy-widget.h"
-#include	"airspy.h"
+#include	"libairspy/airspy.h"
 
 extern "C"  {
 typedef	int (*pfn_airspy_init) (void);
-- 
2.6.2

Places

File 0001-CMake-improvements.patch of Package mingw64-sdr-j-dabreceiver (Revision aaefb0aa6475a041552f40fc69373bc7)

Places