File PKGBUILD of Package compiler-rt21

pkgname=compiler-rt21
pkgver=21.1.3
pkgrel=2
pkgdesc="Compiler runtime libraries for clang 21"
arch=('x86_64')
url="https://compiler-rt.llvm.org/"
license=('Apache-2.0 WITH LLVM-exception')
depends=('gcc-libs')
makedepends=('llvm21' 'cmake' 'ninja' 'python' 'clang' 'mold')
# Build 32-bit compiler-rt libraries on x86_64 (FS#41911)
makedepends_x86_64=('lib32-gcc-libs')
options=('staticlibs')
source=(llvm-project.tar)
b2sums=('SKIP')

prepare() {
  mkdir llvm-project/compiler-rt/build
}

build() {
  cd llvm-project/compiler-rt/build

  local cmake_args=(
    CMAKE_BUILD_TYPE=Release
    CMAKE_INSTALL_PREFIX=/usr/lib/llvm21
    CMAKE_BUILD_WITH_INSTALL_RPATH=ON
    COMPILER_RT_INSTALL_PATH=/usr/lib/llvm21/lib/clang/${pkgver%%.*}

    CMAKE_C_COMPILER=clang
    CMAKE_CXX_COMPILER=clang++
    CMAKE_C_FLAGS="-O3 -march=znver3 -pipe"
    CMAKE_CXX_FLAGS="-O3 -march=znver3 -pipe"
    LLVM_USE_LINKER=mold
  )
  cmake .. -GNinja "${cmake_args[@]/#/-D}"
  ninja
}

package() {
  cd llvm-project/compiler-rt/build

  DESTDIR="$pkgdir" ninja install
  install -Dm644 ../LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et:
Places

File PKGBUILD of Package compiler-rt21

Places
