File PKGBUILD of Package zig-git

pkgname=zig-git
_srcname=zig
pkgver=0.13.0.r3596.gfbb38a7682
 pkgrel=1
pkgdesc='a general-purpose programming language and toolchain for maintaining robust, optimal, and reusable software'
arch=('x86_64')
url='https://ziglang.org/'
license=('MIT')
depends=('clang21' 'lld21' 'llvm21-libs')
makedepends=('llvm21' 'cmake' 'ninja')
options=('!lto')
provides=('zig')
conflicts=('zig')
source=($_srcname.tar)
b2sums=('SKIP')

prepare() {
  sed 's/\(ZIG_VERSION "\)"/\1${ZIG_VERSION_MAJOR}.${ZIG_VERSION_MINOR}.${ZIG_VERSION_PATCH}-dev.'$(echo -n "${pkgver}" | sed -E 's/([0-9]+\.){3}r(.+)/\2/;s/\.g/+/')'"/' -i "$_srcname/CMakeLists.txt"
}

build() {
  ulimit -n 4096

  local cmake_args=(
    CMAKE_BUILD_TYPE=None
    CMAKE_INSTALL_PREFIX=/usr
    CMAKE_PREFIX_PATH=/usr/lib/llvm21

    ZIG_PIE=ON
    ZIG_SHARED_LLVM=ON
    ZIG_USE_LLVM_CONFIG=ON

    ZIG_TARGET_MCPU=znver3
  )

  cmake -B build -GNinja "${cmake_args[@]/#/-D}" "$_srcname"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}