File PKGBUILD of Package mir

pkgname=mir
pkgver=2.20.2
pkgrel=1
pkgdesc="Mir is set of libraries for building Wayland based shells. "
arch=(x86_64)
url="https://github.com/canonical/mir"
license=(GPL-2.0 GPL-3.0 LGPL-3.0)
depends=(
  glibmm
  libxml++2.6
  yaml-cpp
  boost-libs
  glibc
  glib2
  libinput
  egl-wayland
  wayland
  lttng-ust
  freetype2
  libepoxy
  libglvnd
  mesa
  util-linux-libs
  libxcursor
  libdrm
  libxcb
  libxkbcommon-x11
  libx11
  libevdev
	)
makedepends=(
  glm
  glib2-devel
  gtest
  umockdev
  xorg-xwayland
  cmake
  boost
  doxygen
  graphviz
  glmark2
  python-pillow
  python-dbus
  python-dbusmock
)

source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")

build() {
   cd ${pkgname}-${pkgver}
   cmake -B build -Wno-dev \
    -Dglm_DIR:PATH=/usr/lib/cmake/glm/ \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DMIR_ENABLE_WLCS_TESTS=OFF \
    -DMIR_ENABLE_TESTS=OFF \
    -DMIR_BUILD_PERFORMANCE_TESTS=OFF \
    -DMIR_BUILD_PLATFORM_TEST_HARNESS=OFF \
    -DMIR_BUILD_UNIT_TESTS=OFF

    cmake --build build
}

package() {
    cd ${pkgname}-${pkgver}
    DESTDIR="${pkgdir}" cmake --install build
}

sha256sums=('f685fa2c930ed5c3f6e0a8dda1203dd85f7f951d4a648b4f004e80115f48551f')