File PKGBUILD of Package kmscon

# Maintainer: Oleksandr Natalenko <oleksandr@natalenko.name>

pkgname=kmscon
pkgver=9.2.1
pkgrel=2
pkgdesc="KMS/DRM-based virtual console emulator"
arch=(x86_64)
url=https://github.com/kmscon/kmscon
license=(MIT)
depends=(bash glibc glib2 libdrm libgl libtsm libxkbcommon mesa pango systemd-libs)
makedepends=(check libxslt docbook-xsl linux-api-headers meson)
backup=(etc/kmscon/kmscon.conf)
source=(${url}/archive/refs/tags/v${pkgver}.tar.gz
		${url}/commit/8a9cb88a7bb57801c1127ccb26e5d5a1f3706ac9.patch
		${url}/commit/bbd427c8fb0a1292f9077224aa223296becfce63.patch)
sha256sums=('d801a3f0bbfff6940eb249ade41c28307ef846132b4e10a499abe76d535e24e8'
			SKIP
			SKIP)

prepare() {
	cd kmscon-${pkgver}

	patch -Np1 -i ../8a9cb88a7bb57801c1127ccb26e5d5a1f3706ac9.patch
	patch -Np1 -i ../bbd427c8fb0a1292f9077224aa223296becfce63.patch
}

build() {
	arch-meson kmscon-${pkgver} build \
		-D werror=false

	meson compile -C build
}

package() {
	meson install -C build --destdir="${pkgdir}"

	install -Dt "${pkgdir}"/usr/share/licenses/kmscon -m0644 kmscon-${pkgver}/COPYING
}