File PKGBUILD of Package osc

# Maintainer: Oleksandr Natalenko <oleksandr@natalenko.name>

pkgname=osc
pkgver=1.21.0
pkgrel=1
pkgdesc="Command Line Interface for Open Build Service"
arch=(any)
url=https://github.com/openSUSE/osc
license=(GPL-2.0-or-later)
depends=(diffstat python-distro python-urllib3 python-keyring python-cryptography python-progressbar python-ruamel-yaml)
makedepends=(python-setuptools python-argparse-manpage python-sphinx)
source=(${url}/archive/refs/tags/${pkgver}.tar.gz)
sha256sums=('6579381095a8a6675a6ffca4c894a2e5706fe19c45f2e9a18631d75e00bed051')

build() {
	cd ${pkgname}-${pkgver}

	python setup.py build

	# Build manpage, see https://github.com/openSUSE/osc/blob/master/contrib/osc.spec
	PYTHONPATH=. argparse-manpage \
    	--output=osc.1 \
    	--format=single-commands-section \
    	--module=osc.commandline \
    	--function=argparse_manpage_get_parser \
    	--project-name=osc \
    	--prog=osc \
    	--description="openSUSE Commander" \
    	--author="Contributors to the osc project. See the project's GIT history for the complete list." \
    	--url="${url}"

	sphinx-build -b man doc .
}

package() {
	cd ${pkgname}-${pkgver}

	python setup.py install --root="${pkgdir}" --optimize=1 --prefix=/usr

	install -Dt "${pkgdir}"/usr/share/man/man1 -m0644 {git-obs-quickstart,osc}.1
	install -Dt "${pkgdir}"/usr/share/man/man5 -m0644 oscrc.5

	install -Dm0644 contrib/complete.sh "${pkgdir}"/usr/share/bash-completion/completions/osc
	install -Dm0644 contrib/osc.zsh "${pkgdir}"/usr/share/zsh/site-functions/_osc
	install -Dt "${pkgdir}"/usr/share/fish/vendor_completions.d -m0644 contrib/osc.fish
}