File PKGBUILD of Package sendxmpp

# Maintainer: Oleksandr Natalenko <oleksandr@natalenko.name>

pkgname=sendxmpp
pkgver=0.15.3
pkgrel=1
pkgdesc="Send messages and files to XMPP contact and MUC"
arch=(x86_64)
url=https://salsa.debian.org/mdosch/go-sendxmpp
license=(BSD-2-Clause)
makedepends=(go)
source=(${url}/-/archive/v${pkgver}/go-sendxmpp-v${pkgver}.tar.gz
		vendor.tar.zst)
sha256sums=('3e639e39fd483d65886e050198484f2bc8c996c54e02b8ae99c2a0d733b75d5a'
            '5bd5412744ce6fff7b65eb5f9729b0f5caee6a001309d5eb16570a8f61ddab7f')

prepare() {
	cd go-sendxmpp-v${pkgver}

	ln -sf ../vendor vendor
}

build() {
	cd go-sendxmpp-v${pkgver}

	export CGO_CPPFLAGS="${CPPFLAGS}"
	export CGO_CFLAGS="${CFLAGS}"
	export CGO_CXXFLAGS="${CXXFLAGS}"
	export CGO_LDFLAGS="${LDFLAGS}"
	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=vendor -modcacherw -buildvcs=false"
	mkdir build
	go build -o build/sendxmpp .
}

package() {
	cd go-sendxmpp-v${pkgver}

	install -Dt "${pkgdir}"/usr/bin -m0755 build/sendxmpp
	install -Dt "${pkgdir}"/usr/share/licenses/sendxmpp -m0644 LICENSE
	for i in 1 5; do
		install -Dm0644 man/go-sendxmpp.${i} "${pkgdir}"/usr/share/man/man${i}/sendxmpp.${i}
	done
}