File PKGBUILD of Package navidrome-hardened

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package navidrome-hardened

# Maintainer: Oleksandr Natalenko <oleksandr@natalenko.name>

pkgname=navidrome-hardened
pkgver=0.52.5
pkgrel=1
__ffmpeg_build=1712343708_7.0
pkgdesc="Modern Music Server and Streamer compatible with Subsonic/Airsonic"
arch=(x86_64)
url=https://www.navidrome.org
license=(GPL-3.0-or-later)
depends=(taglib)
makedepends=(go npm)
conflicts=(navidrome)
provides=(navidrome)
replaces=(navidrome)
backup=(etc/navidrome/navidrome.toml)
source=(https://github.com/navidrome/navidrome/archive/refs/tags/v${pkgver}.tar.gz
		https://ffmpeg.martin-riedl.de/download/linux/amd64/${__ffmpeg_build}/ffmpeg.zip
		npm_cache.tar.zst
		node_modules.tar.zst
		vendor.tar.zst
		navidrome.service
		navidrome.toml)
sha256sums=('9e5a81589d3e0c04d8cd06dccc680942d082f3d02aa4f0fd2b67dedf9902063b'
            'd9991153dd9da7dbc8bc46bc1932e01d03037bf2fe359e82fdaf78ef8b7c01bc'
            '15a37052ad25e07f0d7284980ac4f287656710c69cb3ee7ee3b221c82f3a10c9'
            '9878f383898c957f56017152f31db7ed3581b1942860bfc5987d8835ac441a10'
            'cd2aeca2af25e7d940d80f0720c58bcdd743ceee944f420a67ebcfb9a883582e'
            'ea2e6c121ed5528b7e88da1ff36d73b2c0366b06969f85d627e9acfa06be41bf'
            '0b2fe97bebb3dd9b2b08f3ab04eec643c60bc3d011267d7f12da3fc8a8316154')

prepare() {
	cd navidrome-${pkgver}

ln -sf ../../.npm_cache ui/.npm_cache
	echo "cache=.npm_cache" >ui/.npmrc
	ln -sf ../../node_modules ui/node_modules

ln -sf ../vendor vendor
}

build() {
	cd navidrome-${pkgver}

cd ui
	npm run build

cd ..

export CGO_CPPFLAGS="${CPPFLAGS}"
	export CGO_CFLAGS="${CFLAGS}"
	export CGO_CXXFLAGS="${CXXFLAGS}"
	export CGO_LDFLAGS="${LDFLAGS}"
	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=vendor -modcacherw -buildvcs=false"
	mkdir build
	go build -o build/navidrome .
}

package() {
	cd navidrome-${pkgver}

install -Dt "${pkgdir}"/usr/bin -m0755 build/navidrome
	install -Dt "${pkgdir}"/usr/libexec/navidrome -m0755 ../ffmpeg
	install -Dt "${pkgdir}"/etc/navidrome -m0644 ../navidrome.toml
	install -Dt "${pkgdir}"/usr/lib/systemd/system -m0644 ../navidrome.service
}

Places

File PKGBUILD of Package navidrome-hardened

Places