File PKGBUILD of Package ethtool-static

# Maintainer: Oleksandr Natalenko <oleksandr@natalenko.name>

_libmnl_name=libmnl
_libmnl_ver=1.0.5
pkgname=ethtool-static
pkgver=6.15
pkgrel=1
epoch=1
pkgdesc="Utility for controlling network drivers and hardware"
arch=(x86_64)
url=https://www.kernel.org/pub/software/network/ethtool
license=(GPL-2.0-only)
makedepends=(kernel-headers-musl musl)
source=(https://www.kernel.org/pub/software/network/ethtool/ethtool-${pkgver}.tar.xz
		https://www.netfilter.org/projects/libmnl/files/libmnl-${_libmnl_ver}.tar.bz2)
sha256sums=('9477c365114d910120aaec5336a1d16196c833d8486f7c6da67bedef57880ade'
            '274b9b919ef3152bfb3da3a13c950dd60d6e2bcd54230ffeca298d03b40d0525')

build() {
	cd libmnl-${_libmnl_ver}
	CC=musl-gcc \
		./configure \
			--enable-static \
			--disable-shared
	make

	cd ..

	cd ethtool-${pkgver}
	CC=musl-gcc LDFLAGS=-static \
		MNL_CFLAGS="-I${srcdir}/libmnl-${_libmnl_ver}/include" \
		MNL_LIBS="-L${srcdir}/libmnl-${_libmnl_ver}/src/.libs -lmnl" \
		./configure

	make
}

package() {
	cd ethtool-${pkgver}

	install -Dt "${pkgdir}"/usr/libexec/xk-project/runtime/xk-rcinit/bin -m0755 ethtool
}