File PKGBUILD of Package aehostd-modules

# Maintainer: Michael Ströder <michael@stroeder.com>

pkgname=aehostd-modules
pkgver=0.9.12
pkgrel=1

pkgdesc='NSS and PAM modules for aehostd (AE-DIR)'
url="https://arthurdejong.org/nss-pam-ldapd/"
arch=('x86_64')
license=('LGPL2.1')
makedepends=('gzip' 'curl')
depends=('pam' 'libsasl' 'libldap')
source=("https://arthurdejong.org/nss-pam-ldapd/nss-pam-ldapd-${pkgver}.tar.gz"{,.sig})
sha512sums=('5eca4851a9bcb2779548d193a363a143d6106bfc6463b8d3f0c2d5d7d227ec1e680861383d4813f40b44d1be2ce5f7ed019d838f7f6796e15f96f7411d3bb8f6'
            'SKIP')
validpgpkeys=('452EC2CB65CF68C2A1ADBF5F2A8B746810E0AFC1')

prepare() {
  cd nss-pam-ldapd-${pkgver}
}

build() {
  cd nss-pam-ldapd-${pkgver}
  CFLAGS=""
  export CFLAGS
  ./configure \
    --prefix=/usr \
    --sbindir=/usr/bin \
    --sysconfdir=/etc \
    --with-pam-seclib-dir=/usr/lib/security \
    --with-module-name=aedir \
    --disable-nslcd --disable-pynslcd --disable-kerberos \
    --disable-utils \
    --with-nss-maps=passwd,group,hosts \
    --with-nslcd-socket=/var/run/aehostd/aehostd.sock
  make
}

package() {
  cd nss-pam-ldapd-${pkgver}
  make DESTDIR="${pkgdir}" install
}