File PKGBUILD of Package cargo-vet

# Maintainer: Sebastian Wiesner <sebastian@swsnr.de>

pkgname=cargo-vet
pkgver=0.10.2
pkgrel=1
pkgdesc='Supply-chain security for Rust'
arch=('i686' 'x86_64')
url="https://github.com/mozilla/cargo-vet"
license=('Apache-2.0 OR MIT')
depends=('cargo')
conflicts=()
makedepends=('git')
options=("!lto")
source=(
    git+${url}.git#tag=v${pkgver}
    "vendor.tar.zst"
)
sha512sums=('f4109f0685776cbd6983c032801cead842b9585e1c7ebd49d5f40383345eeaf83f8b5e3521388ca89b3fbea649b5a0830d875940898c052e22c0b2f485ece7a7'
            'ffba638462978004ab9208343718044465082cc4c4b8c6215277efa7506e440432ee3c503f472468295571e319885c2f9083538f56ab635ced15893830e4b7d3')

prepare() {
    cd "${pkgname}" || return 1

    mkdir -p .cargo
    cat > .cargo/config.toml <<EOF
[source.crates-io]
replace-with = "vendored-sources"

[source.vendored-sources]
directory = "../vendor"
EOF
}

build() {
    cd "${pkgname}" || return 1
    cargo build --release --locked
}

package() {
    install -Dm755 -t "${pkgdir}/usr/bin/" "${srcdir}/${pkgname}/target/release/${pkgname}"
}